iniciar-programa
define-nueva-instruccion gira(q) como repetir q veces gira-izquierda;
define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;
define-nueva-instruccion compara(x) como inicio
    si no si-es-cero(x) entonces inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            compara(precede(x));
            deja-zumbador;
        fin;
    fin sino inicio
        mientras junto-a-zumbador hacer coge-zumbador;
    fin;
fin;
define-nueva-instruccion busqueda(x) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        si no junto-a-zumbador entonces inicio
            repetir x veces deja-zumbador;
        fin sino inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                compara(x);
            fin;
        fin;
        repetir 2 veces deja-zumbador;
    fin sino inicio
        repetir 2 veces deja-zumbador;
        este;
        si frente-libre entonces inicio
            avanza;
            busqueda(sucede(x));
            oeste;
            avanza;
        fin;
        sur;
        si frente-libre entonces inicio
            avanza;
            busqueda(sucede(x));
            norte;
            avanza;
        fin;
        oeste;
        si frente-libre entonces inicio
            avanza;
            busqueda(sucede(x));
            este;
            avanza;
        fin;
        norte;
        si frente-libre entonces inicio
            avanza;
            busqueda(sucede(x));
            sur;
            avanza;
        fin;
        si junto-a-zumbador entonces repetir 2 veces coge-zumbador;
    fin;
fin;
define-nueva-instruccion quita(x) como inicio
    si no si-es-cero(x) entonces inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            quita(precede(x));
        fin sino inicio
            quita(precede(x));
            deja-zumbador;
        fin;
    fin sino inicio
        mientras junto-a-zumbador hacer coge-zumbador;
    fin;
fin;
define-nueva-instruccion resta(x) como inicio
    si no si-es-cero(x) entonces inicio
        si frente-libre y orientado-al-sur entonces inicio
            avanza;
            resta(precede(x));
        fin sino inicio
            norte;
            fin;
    fin;
fin;
define-nueva-instruccion camino(x) como inicio
    si  frente-libre entonces inicio
        avanzA;
        camino(sucede(x));
    fin sino inicio
        si orientado-al-norte entonces inicio
            sur;
            mientras no junto-a-zumbador y frente-libre hacer avanza;
            resta(x);
            si orientado-al-sur entonces inicio
                norte;
                mientras no junto-a-zumbador y frente-libre hacer avanza;
                este;
                camino(x);
            fin sino inicio
                mientras frente-libre y no junto-a-zumbador hacer avanza;
                sur;
            fin;
        fin sino inicio
            si orientado-al-sur entonces inicio
                norte;
                mientras no junto-a-zumbador y frente-libre hacer avanza;
                este;
                camino(x);
            fin;
        fin;
        si orientado-al-este y frente-bloqueado entonces inicio
            oeste;
            mientras no junto-a-zumbador y frente-libre hacer avanza;
            quita(x);
        fin;
    fin;
fin;
define-nueva-instruccion salida como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        si junto-a-zumbador entonces inicio
            coge-zumbador;
             gira(1);
             camino(0);
             si orientado-al-sur entonces inicio
                 camino(0);
             fin;
             apagate;
        fin sino inicio
            deja-zumbador;
        fin;
    fin sino inicio
        deja-zumbador;
        este;
        si frente-libre entonces inicio
            avanza;
            salida;
            oeste;
            avanza;
        fin;
        sur;
        si frente-libre entonces inicio
            avanza;
            salida;
            norte;
            avanza;
        fin;
        oeste;
        si frente-libre entonces inicio
            avanza;
            salida;
            este;
            avanza;
        fin;
        norte;
        si frente-libre entonces inicio
            avanza;
            salida;
            sur;
            avanza;
        fin;
        coge-zumbador;
    fin;
fin;
    inicia-ejecucion
        busqueda(0);
        salida;
        apagate;
    termina-ejecucion
finalizar-programa
