iniciar-programa

    define-nueva-instruccion norte como inicio
       mientras no-orientado-al-norte hacer inicio
          gira-izquierda;
       fin;
    fin;

    define-nueva-instruccion sur como inicio
       mientras no-orientado-al-sur hacer inicio
          gira-izquierda;
       fin;
    fin;

    define-nueva-instruccion este como inicio
       mientras no-orientado-al-este hacer inicio
          gira-izquierda;
       fin;
    fin;

    define-nueva-instruccion oeste como inicio
       mientras no-orientado-al-oeste hacer inicio
          gira-izquierda;
       fin;
    fin;

    define-nueva-instruccion revisa como inicio
        repetir 4 veces inicio
              gira-izquierda;
              si frente-bloqueado y izquierda-bloqueada y derecha-bloqueada entonces inicio
                  si no junto-a-zumbador entonces inicio
                      deja-zumbador;
                  fin;
                  gira-izquierda;
                  gira-izquierda;
                  si frente-bloqueado entonces inicio
                      mientras junto-a-zumbador hacer inicio
                          coge-zumbador;
                      fin;
                  fin;
                  apagate;
              fin;
          fin;
      fin;

    define-nueva-instruccion checa como inicio
        si frente-bloqueado y izquierda-bloqueada y derecha-bloqueada entonces inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si no junto-a-zumbador entonces inicio
                    deja-zumbador;
                fin sino inicio
                    deja-zumbador;
                fin;
            fin sino inicio
                deja-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion busca como inicio
        si no junto-a-zumbador entonces inicio
            deja-zumbador;
            norte;
            si frente-libre entonces inicio
                avanza;
                si frente-bloqueado y derecha-bloqueada y izquierda-bloqueada entonces inicio
                si no junto-a-zumbador entonces inicio
                    deja-zumbador;
                    deja-zumbador;
                    fin;
                fin;
                busca;
                sur;                  
                avanza;
            fin;
            sur;
            si frente-libre entonces inicio
                avanza;
                si frente-bloqueado y derecha-bloqueada y izquierda-bloqueada entonces inicio
                    si no junto-a-zumbador entonces inicio
                        deja-zumbador;
                        deja-zumbador;
                    fin;
                fin;    
                busca;
                norte;
                avanza;
            fin;
            este;
            si frente-libre entonces inicio
                avanza;
                si frente-bloqueado y derecha-bloqueada y izquierda-bloqueada entonces inicio
                    si no junto-a-zumbador entonces inicio
                        deja-zumbador;
                        deja-zumbador;
                    fin;
                fin;
                busca;
                oeste;
                avanza;
            fin;
            oeste;
            si frente-libre entonces inicio
                avanza;
                si frente-bloqueado y derecha-bloqueada y izquierda-bloqueada entonces inicio
                    si no junto-a-zumbador entonces inicio
                        deja-zumbador;
                        deja-zumbador;
                    fin;
                fin;
                busca;
                este;
                avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion quita como inicio
        checa;
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            norte;
            si frente-libre entonces inicio
                avanza;
                checa;
                quita;
                sur;
                avanza;
            fin;
            sur;
            si frente-libre entonces inicio
                avanza;
                checa;
                quita;
                norte;
                avanza;
            fin;
            este;
            si frente-libre entonces inicio
                avanza;
                checa;
                quita;
                oeste;
                avanza;
            fin;
            oeste;
            si frente-libre entonces inicio
                avanza;
                checa;
                quita;
                este;
                avanza;
            fin;
        fin;
    fin;
    inicia-ejecucion
        busca;
        quita;
        revisa;
        apagate;
    termina-ejecucion
finalizar-programa
