iniciar-programa
    define-nueva-instruccion gira (n) como inicio
        repetir n veces
            gira-izquierda;
    fin;
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer
            gira(1);
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer
            gira(1);
    fin;
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer
            gira(1);
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer
            gira(1);
    fin;
    define-nueva-instruccion busca como inicio
        si no-junto-a-zumbador entonces inicio
            repetir 2 veces
                deja-zumbador;
            norte;
            si frente-libre entonces inicio
               avanza;
               si no-junto-a-zumbador entonces
                  busca;
               sur;
               avanza;
            fin;
            sur;
            si frente-libre entonces inicio
               avanza;
               si no-junto-a-zumbador entonces
                  busca;
               norte;
               avanza;
            fin;
            este;
            si frente-libre entonces inicio
               avanza;
               si no-junto-a-zumbador entonces
                  busca;
               oeste;
               avanza;
            fin;
            oeste;
            si frente-libre entonces inicio
               avanza;
               si no-junto-a-zumbador entonces
                  busca;
               este;
               avanza;
            fin;
            norte;
            repetir 2 veces
                coge-zumbador;
            repetir 4 veces inicio
                si frente-bloqueado y izquierda-bloqueada y derecha-bloqueada y no-junto-a-zumbador entonces
                    deja-zumbador;
                gira(1);
            fin;
            si frente-bloqueado entonces inicio
                gira(1);
                si frente-bloqueado entonces inicio
                    gira(1);
                    si frente-bloqueado entonces inicio
                        gira(1);
                        si frente-bloqueado entonces inicio
                            gira(1);
                            si junto-a-zumbador entonces
                                coge-zumbador;
                        fin;
                    fin;
                fin;
            fin;
            repetir 2 veces
                deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion quita2 como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                norte;
                si frente-libre entonces inicio
                   avanza;
                   si junto-a-zumbador entonces
                      quita2;
                   sur;
                   avanza;
                fin;
                sur;
                si frente-libre entonces inicio
                   avanza;
                   si junto-a-zumbador entonces
                      quita2;
                   norte;
                   avanza;
                fin;
                este;
                si frente-libre entonces inicio
                   avanza;
                   si junto-a-zumbador entonces
                      quita2;
                   oeste;
                   avanza;
                fin;
                oeste;
                si frente-libre entonces inicio
                   avanza;
                   si junto-a-zumbador entonces
                      quita2;
                   este;
                   avanza;
                fin;
            fin
            sino inicio
                deja-zumbador;
            fin;
        fin;
    fin;
    inicia-ejecucion
        busca;
        quita2;
        apagate;
    termina-ejecucion
finalizar-programa