iniciar-programa
    define-nueva-instruccion g(n) como
        repetir n veces
            gira-izquierda;
    define-nueva-instruccion prueba como
    inicio
        repetir 4 veces
        inicio
            si frente-bloqueado y izquierda-bloqueada y derecha-bloqueada entonces
            inicio
                si no junto-a-zumbador entonces
                    deja-zumbador
                sino
                    mientras junto-a-zumbador hacer
                        coge-zumbador;
            fin;
            g(1);
        fin;
    fin;
    define-nueva-instruccion pon como
    inicio
        prueba;
        repetir 2 veces
            deja-zumbador;

        repetir 4 veces
        inicio
            si frente-libre entonces
            inicio
                avanza;
                si no junto-a-zumbador entonces
                inicio
                    pon;
                fin;
                g(2);
                avanza;
                g(2);
            fin;
            g(1);
        fin;
    fin;
    define-nueva-instruccion quita como
    inicio
        repetir 2 veces
            coge-zumbador;
        repetir 4 veces
        inicio
            si frente-libre entonces
            inicio
                avanza;
                si junto-a-zumbador entonces
                inicio
                    coge-zumbador;
                    si junto-a-zumbador entonces
                    inicio
                        deja-zumbador;
                        quita;
                    fin
                    sino
                        deja-zumbador;
                fin;
                g(2);
                avanza;
                g(2);
            fin;
            g(1);
        fin;
    fin;
    inicia-ejecucion
        pon;
        quita;
        apagate;
    termina-ejecucion
finalizar-programa
