iniciar-programa
    define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;

    define-nueva-instruccion klaveles como inicio
        si no-junto-a-zumbador entonces inicio
            si frente-bloqueado y izquierda-bloqueada y derecha-bloqueada entonces inicio
                gira(2);
                si frente-bloqueado entonces inicio
                    apagate;
                fin sino inicio
                    deja-zumbador;
                    gira(2);
                    repetir 4 veces inicio
                        gira-izquierda;
                        si frente-libre entonces inicio
                            avanza;
                            klaveles;
                            gira(2);
                            avanza;
                            gira(2);
                        fin;
                    fin;
                fin;
            fin sino inicio
                repetir 2 veces deja-zumbador;
                repetir 4 veces inicio
                    gira-izquierda;
                    si frente-libre entonces inicio
                        avanza;
                        klaveles;
                        gira(2);
                        avanza;
                        gira(2);
                    fin;
                fin;
            fin;
        fin sino inicio
            si frente-bloqueado y izquierda-bloqueada y derecha-bloqueada entonces inicio
                mientras junto-a-zumbador hacer coge-zumbador;
                deja-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion limpiar como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si no-junto-a-zumbador entonces inicio
                deja-zumbador;
                repetir 4 veces inicio
                    gira-izquierda;
                    si frente-libre entonces inicio
                        avanza;
                        limpiar;
                        gira(2);
                        avanza;
                        gira(2);
                    fin;
                fin;
            fin sino inicio
                coge-zumbador;
                repetir 4 veces inicio
                    gira-izquierda;
                    si frente-libre entonces inicio
                        avanza;
                        limpiar;
                        gira(2);
                        avanza;
                        gira(2);
                    fin;
                fin;
            fin;
        fin;
    fin;

    inicia-ejecucion
        klaveles;
        limpiar;
        apagate;
    termina-ejecucion
finalizar-programa
