iniciar-programa
define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

define-nueva-instruccion sube(k) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        sube(sucede(k));
        deja-zumbador;
    fin sino inicio
        norte;
        avanza;
    fin;
fin;

define-nueva-instruccion baja(k) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        baja(sucede(k));
    fin sino inicio
        repetir k veces deja-zumbador;
        avanza;
        repetir k veces coge-zumbador;
    fin;
fin;

define-nueva-instruccion quita(n) como inicio
    si no si-es-cero(n) y junto-a-zumbador entonces inicio
        coge-zumbador;
        quita(precede(n));
        deja-zumbador;
    fin sino inicio
        este;
        si frente-libre entonces inicio
            avanza;
            sur;
            avanza;
        fin;
    fin;
fin;

define-nueva-instruccion sobrecupo(k) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        sobrecupo(sucede(k));
        deja-zumbador;
    fin sino inicio
        sur;
        avanza;
    fin;
fin;

define-nueva-instruccion lleva(k) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        lleva(sucede(k));
        deja-zumbador;
    fin sino inicio
        avanza;
        sobrecupo(0);
        norte;
        avanza;
        este;
    fin;
fin;

define-nueva-instruccion toma(n) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        toma(sucede(n));
    fin sino inicio
        repetir n veces deja-zumbador;
        avanza;
        sur;
        avanza;
        sube(0);
        avanza;
        sur;
        baja(0);
        si izquierda-libre entonces inicio
            quita(n);
            oeste;
            avanza;
            sur;
            norte;
            avanza;
            oeste;
            avanza;
            este;
            lleva(0);
        fin sino inicio
            oeste;
            avanza;
            mientras junto-a-zumbador hacer coge-zumbador;
            este;
            avanza;
        fin;
    fin;
fin;

    inicia-ejecucion
    mientras frente-libre hacer inicio
        toma(0);
    fin;
        apagate;
    termina-ejecucion
finalizar-programa
