iniciar-programa
    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion llevar como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            llevar;
            deja-zumbador;
        fin sino inicio
            este;
            mientras frente-libre hacer avanza;
        fin;
    fin;
    define-nueva-instruccion b(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            b(sucede(n));
            deja-zumbador;
        fin sino inicio
            repetir n veces deja-zumbador;
            sur;
            avanza;
            norte;
        fin;
    fin;
    define-nueva-instruccion pos como inicio
        si orientado-al-norte entonces inicio
            sur;
            avanza;
        fin sino inicio norte; avanza; fin;
    fin;
    define-nueva-instruccion resum(n) como inicio
        si orientado-al-este entonces inicio
            pos;
            b(0);
        fin;
        si no orientado-al-oeste entonces inicio
            si orientado-al-norte y junto-a-zumbador entonces inicio
                coge-zumbador;
                resum(sucede(n));
             fin;
             si orientado-al-norte entonces inicio
                 pos;
             fin;
             si orientado-al-sur y junto-a-zumbador y no si-es-cero(n) entonces inicio
                 coge-zumbador;
                 resum(precede(n));
            fin sino inicio
                norte;
                avanza;
                este;
                si frente-libre entonces inicio
                    avanza;
                    resum(n);
                fin sino inicio
                    oeste;
                    mientras frente-libre hacer avanza;
                    repetir n veces coge-zumbador;
                    llevar;
                    apagate;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion baja(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            baja(sucede(n));
        fin sino inicio
            repetir n veces deja-zumbador;
            avanza;
            resum(n);
        fin;
    fin;
    inicia-ejecucion
        baja(0);
        apagate;
    termina-ejecucion
finalizar-programa
