iniciar-programa

define-nueva-instruccion come como mientras junto-a-zumbador hacer coge-zumbador;
define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
define-nueva-instruccion media-vuelta como repetir 2 veces gira-izquierda;
define-nueva-instruccion choca como mientras frente-libre hacer avanza;

define-nueva-instruccion deja(n) como inicio
    si no si-es-cero(n) entonces inicio
        deja-zumbador;
        deja(sucede(n));
    fin;
fin;

define-nueva-instruccion sube(n) como inicio
    si no si-es-cero(n) entonces inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            sube(sucede(n));
        fin;
    fin;
fin;

define-nueva-instruccion quita(n) como inicio
    si no si-es-cero(n) entonces inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            quita(sucede(n));
        fin;
    fin;
fin;



define-nueva-instruccion final como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        final;
        deja-zumbador;
    fin sino inicio
        choca;
    fin;
fin;


define-nueva-instruccion pasa como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        pasa;
        deja-zumbador;
    fin sino inicio
        sur; avanza;
    fin;
fin;


define-nueva-instruccion acomoda como inicio
    si junto-a-zumbador entonces inicio
        pasa;
        norte; avanza;
        oeste;
        acomoda;
    fin sino inicio
        si frente-libre entonces inicio
            avanza;
            acomoda;
        fin sino inicio
            sur; avanza; avanza;
            este;
            final; apagate;
        fin;
    fin;
fin;


define-nueva-instruccion ruta(n) como inicio
    si orientado-al-este entonces inicio
       si frente-libre entonces inicio
           avanza;
           si frente-bloqueado entonces inicio
               oeste; choca;
               quita(n);
               este; choca; norte; avanza;
               avanza;
               oeste;
               acomoda;
               apagate;
           fin;
       fin;
    fin;
    si no-orientado-al-sur y no-orientado-al-norte entonces inicio
        norte; avanza;
    fin;
    si orientado-al-norte entonces inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            avanza; deja-zumbador; sur; avanza;
            norte;
            ruta(precede(n));
        fin sino inicio
            sur; avanza; avanza;
        fin;
    fin;
    si no si-es-cero(n) y orientado-al-sur entonces inicio
       si junto-a-zumbador entonces inicio
            coge-zumbador;
            ruta(sucede(n));
        fin sino inicio
            norte; avanza;
            este;
            ruta(n);
        fin;
    fin sino inicio
        si orientado-al-sur entonces inicio
            norte; avanza;
            este;
            ruta(n);
        fin;
    fin;
fin;

define-nueva-instruccion kamion(n) como inicio
    si junto-a-zumbador entonces inicio
         coge-zumbador;
         kamion(precede(n));
    fin sino inicio
        deja(n);
        ruta(n);
    fin;
fin;

    inicia-ejecucion
        kamion(0);
        apagate;
    termina-ejecucion
finalizar-programa
