iniciar-programa
    define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;

    define-nueva-instruccion mueve como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            mueve;
            deja-zumbador;
        fin sino inicio
            avanza;
        fin;
    fin;

    define-nueva-instruccion capacidad(personas) como inicio
        si junto-a-zumbador entonces inicio
            si orientado-al-norte entonces inicio
                coge-zumbador;
                avanza;
                deja-zumbador;
                gira(2);
                avanza;
                gira(2);
                capacidad(sucede(personas));
            fin sino inicio
                si no si-es-cero(personas) entonces inicio
                    coge-zumbador;
                    capacidad(precede(personas));
                fin sino inicio
                    gira(2);
                    avanza;
                    gira(3);
                    si frente-libre entonces inicio
                        avanza;
                        gira(1);
                        avanza;
                        capacidad(personas);
                    fin sino inicio
                    fin;
                fin;
            fin;
        fin sino inicio
            si orientado-al-norte entonces inicio
                avanza;
                gira(2);
                si junto-a-zumbador entonces inicio
                    mueve;
                fin sino inicio
                    avanza;
                fin;
                repetir 2 veces avanza;
                capacidad(personas);
            fin;
            si orientado-al-sur entonces inicio
                gira(2);
                avanza;
                gira(3);
                si frente-libre entonces inicio
                    avanza;
                    gira(1);
                    avanza;
                    capacidad(personas);
                fin sino inicio
                    repetir personas veces coge-zumbador;
                    apagate;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion contar(personas) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            contar(sucede(personas));
        fin sino inicio
            mientras frente-libre hacer avanza;
            repetir personas veces deja-zumbador;
            gira(2);
            mientras frente-libre hacer avanza;
            gira(2);
            avanza;
            gira(1);
            avanza;
            capacidad(personas);
        fin;
    fin;

    inicia-ejecucion
        contar(0);
    termina-ejecucion
finalizar-programa
