iniciar-programa
define-nueva-instruccion gira(n) como
inicio
    repetir n veces gira-izquierda;
fin;

define-nueva-instruccion pow(x) como
inicio
    si junto-a-zumbador y orientado-al-este entonces
    inicio
        coge-zumbador;
        gira(1);
        avanza;
        deja-zumbador;
        gira(2);
        avanza;
        gira(1);
        pow(sucede(x));
    fin
    sino
    inicio
        si frente-libre y orientado-al-este entonces
        inicio
            avanza;
            si algun-zumbador-en-la-mochila entonces
            inicio
                gira(1);
                avanza;
                pow(x);
            fin
            sino
            inicio
                gira(3);
                avanza;
                pow(x);
            fin;
        fin
        sino
        inicio
            si frente-bloqueado y orientado-al-este entonces
            inicio
                mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
                apagate;
            fin;
            si orientado-al-norte entonces
            inicio
                si junto-a-zumbador entonces
                inicio
                    coge-zumbador;
                    avanza;
                    deja-zumbador;
                    avanza;
                    deja-zumbador;
                    gira(2);
                    repetir 2 veces avanza;
                    gira(2);
                    pow(sucede(x));
                fin
                sino
                inicio
                    avanza;
                    mientras junto-a-zumbador hacer
                    inicio
                        coge-zumbador;
                        gira(2);
                        avanza;
                        deja-zumbador;
                        gira(2);
                        avanza;
                    fin;
                    gira(2);
                    repetir 3 veces avanza;
                fin;
            fin;
            si orientado-al-sur entonces
            inicio
                si no si-es-cero(x) y junto-a-zumbador entonces
                inicio
                    coge-zumbador;
                    pow(precede(x));
                fin
                sino
                inicio
                   gira(2);
                   avanza;
                   gira(3);
                   pow(x);
                fin;
            fin;
        fin;
    fin;
fin;

    inicia-ejecucion
    pow(0);
        apagate;
    termina-ejecucion
finalizar-programa
