iniciar-programa
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer inicio
            gira-izquierda;
        fin;
    fin;
       define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer inicio
            gira-izquierda;
        fin;
    fin;
       define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer inicio
            gira-izquierda;
        fin;
    fin;
       define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion media-vuelta como inicio
        gira-izquierda;
        gira-izquierda;
    fin;
    define-nueva-instruccion seguir como inicio
        mientras junto-a-zumbador hacer inicio
            avanza;
        fin;
    fin;
    define-nueva-instruccion distancia(n) como inicio
        repetir n veces inicio
            avanza;
        fin;
    fin;
    define-nueva-instruccion bajar-este como inicio
        sur;
        avanza;
        este;
        avanza;
        mientras no-junto-a-zumbador hacer inicio
            deja-zumbador;
            sur;
            avanza;
            este;
            avanza;
        fin;
    fin;
    define-nueva-instruccion bajar-oeste como inicio
        oeste;
        avanza;
        sur;
        avanza;
        mientras no-junto-a-zumbador hacer inicio
            deja-zumbador;
            oeste;
            avanza;
            sur;
            avanza;
        fin;
    fin;
    define-nueva-instruccion subir-oeste como inicio
        norte;
        avanza;
        oeste;
        avanza;
        mientras no-junto-a-zumbador hacer inicio
            deja-zumbador;
            norte;
            avanza;
            oeste;
            avanza;
        fin;
    fin;
    define-nueva-instruccion subir-este como inicio
        este;
        avanza;
        norte;
        avanza;
        mientras no-junto-a-zumbador hacer inicio
            deja-zumbador;
            este;
            avanza;
            norte;
            avanza;
        fin;
    fin;

    define-nueva-instruccion construir como inicio
        si orientado-al-norte entonces inicio
            bajar-este;
            bajar-oeste;
            subir-oeste;
            subir-este;
        fin;
        si orientado-al-sur entonces inicio
            subir-oeste;
            subir-este;
            bajar-este;
            bajar-oeste;
        fin;
        si orientado-al-este entonces inicio
            bajar-oeste;
            subir-oeste;
            subir-este;
            bajar-este;
        fin;
        si orientado-al-oeste entonces inicio
            subir-este;
            bajar-este;
            bajar-oeste;
            subir-oeste;
        fin;
    fin;
    define-nueva-instruccion kabola(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            kabola(sucede(n));
        fin sino inicio
            repetir n veces inicio
                avanza;
            fin;
            deja-zumbador;
            media-vuelta;
            repetir n veces inicio
                avanza;
                avanza;
            fin;
            deja-zumbador;
            media-vuelta;
            repetir n veces inicio
                avanza;
            fin;
            gira-izquierda;
            repetir n veces inicio
                avanza;
            fin;
            deja-zumbador;
            media-vuelta;
            repetir n veces inicio
                avanza;
                avanza;
            fin;
            deja-zumbador;
        fin;
        construir;
        media-vuelta;
        distancia(n);
        apagate;
    fin;
    inicia-ejecucion
        si junto-a-zumbador entonces inicio
            kabola(0);
            construir;
        fin sino inicio
            deja-zumbador;
        fin;
        apagate;
    termina-ejecucion
finalizar-programa


