iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion corre como mientras frente-libre hacer avanza;
    define-nueva-instruccion haz-kabola(n) como inicio
        norte;
        repetir n veces avanza;
        deja-zumbador;
        sur;
        repetir 2 veces repetir  n veces avanza;
        si no-junto-a-zumbador entonces deja-zumbador;
        norte;
        repetir n veces avanza;
        este;
        si no si-es-cero(n) entonces inicio
            avanza;
            haz-kabola(precede(n));
            avanza;
        fin sino inicio
            oeste;
        fin;
    fin;
    define-nueva-instruccion mitad(n) como inicio
        norte;
        repetir n veces avanza;
        si no-junto-a-zumbador entonces deja-zumbador;
        sur;
        repetir 2 veces repetir  n veces avanza;
        si no-junto-a-zumbador entonces deja-zumbador;
        norte;
        repetir n veces avanza;
        oeste;
        si no si-es-cero(n) entonces inicio
            avanza;
            mitad(precede(n));
            avanza;
        fin sino inicio
            este;
        fin;
    fin;
    define-nueva-instruccion agarra(n) como inicio
        si no no-junto-a-zumbador entonces inicio
            coge-zumbador;
            agarra(sucede(n));
        fin sino inicio
            este;
            haz-kabola(n);
            oeste;
            mitad(n);
        fin;
    fin;
    inicia-ejecucion
        agarra(0);
        apagate;
    termina-ejecucion
finalizar-programa
