iniciar-programa
define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion cuenta(x) como
    inicio
        si junto-a-zumbador entonces coge-zumbador;
        norte;
        avanza;
        si junto-a-zumbador entonces
            inicio
                sur;
                avanza;
                repetir x veces deja-zumbador;
            fin
            sino
                inicio
                    sur;
                    avanza;
                    oeste;
                    avanza;
                    cuenta(sucede(x));
                fin;
    fin;
define-nueva-instruccion ubica como
    inicio
        oeste;
        mientras frente-libre hacer avanza;
        sur;
        si frente-bloqueado entonces apagate;
        avanza;
        este;
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
        si junto-a-zumbador entonces
            inicio
                oeste;
                cuenta(1);
                si junto-a-zumbador entonces ubica;
            fin
            sino
                inicio
                    apagate;
                fin;
    fin;
    inicia-ejecucion
        ubica;
        apagate;
    termina-ejecucion
finalizar-programa
