iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion decenas como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            decenas;
            repetir 10 veces deja-zumbador;
        fin sino
        inicio
            este;
            avanza;
        fin;
    fin;

    define-nueva-instruccion unidades como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            unidades;
            deja-zumbador;
        fin sino
        inicio
            avanza;
            decenas;
        fin;
    fin;

    define-nueva-instruccion orientar como
    inicio
        este;
        mientras frente-libre hacer avanza;
        sur;
        mientras frente-libre hacer avanza;
        norte;
        avanza;
        oeste;
    fin;

    define-nueva-instruccion asiento como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            asiento;
            si frente-bloqueado entonces
            inicio
                norte;
                si frente-libre entonces
                inicio
                    avanza;
                    si izquierda-bloqueada entonces este sino oeste;
                fin sino orientar;
            fin sino avanza;
       fin sino
       inicio
           norte;
           avanza;
           oeste;
       fin;
   fin;

   define-nueva-instruccion cine como
   inicio
       oeste;
       mientras frente-libre hacer avanza;
       repetir 99 veces coge-zumbador;
       este;
       mientras frente-libre hacer avanza;
       oeste;
       unidades;
       coge-zumbador;
       asiento;
   fin;

    inicia-ejecucion
        cine;
        apagate;
    termina-ejecucion
finalizar-programa
