iniciar-programa
define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;

define-nueva-instruccion ir2 como
 inicio
  este;
  mientras frente-libre hacer avanza;
  oeste;
  avanza;
 fin;

define-nueva-instruccion convertir como
 inicio
  si junto-a-zumbador entonces
   inicio
     coge-zumbador;
     convertir;
     repetir 10 veces coge-zumbador;
   fin
    sino
     inicio
      mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
      mientras frente-libre hacer avanza;
     fin;
 fin;

define-nueva-instruccion juntar como
 inicio
  este;
  mientras frente-libre hacer avanza;
  mientras junto-a-zumbador hacer coge-zumbador;
  norte;
  avanza;
 fin;

define-nueva-instruccion dejar como
 inicio
  si derecha-bloqueada entonces oeste
  sino este;
   mientras algun-zumbador-en-la-mochila hacer
    inicio
     deja-zumbador;
     si frente-libre y algun-zumbador-en-la-mochila entonces avanza
     sino sal-de-instruccion;
    fin;
 fin;

define-nueva-instruccion regreso como
 inicio
  este;
  mientras frente-libre hacer avanza;
  sur;
  mientras frente-libre hacer avanza;
  norte;
  avanza;
 fin;

define-nueva-instruccion siguiente como
 inicio
  norte;
  si frente-libre entonces avanza
   sino
    inicio
     regreso;
     sal-de-instruccion;
    fin;
 fin;
    inicia-ejecucion
       ir2;
       convertir;
       juntar;
       mientras algun-zumbador-en-la-mochila hacer
        inicio
         dejar;
         si algun-zumbador-en-la-mochila entonces siguiente;
        fin;
        apagate;
    termina-ejecucion
finalizar-programa
