iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion paso como inicio
        si frente-libre entonces inicio
            avanza;
        fin sino inicio
            si orientado-al-este entonces inicio
                si izquierda-libre entonces inicio
                    norte;
                    avanza;
                    oeste;
                fin sino inicio
                    sur;
                    mientras frente-libre hacer avanza;
                    norte;
                    avanza;
                    oeste;
                fin;
            fin sino inicio
                si derecha-libre entonces inicio
                    norte;
                    avanza;
                    este;
                fin sino inicio
                    sur;
                    mientras frente-libre hacer avanza;
                    este;
                    mientras frente-libre hacer avanza;
                    sur;
                    mientras frente-libre hacer avanza;
                    norte;
                    avanza;
                    oeste;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion completa como inicio
        mientras algun-zumbador-en-la-mochila hacer inicio
            paso;
            deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion cuenta(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cuenta(sucede(sucede(sucede(sucede(sucede(sucede(sucede(sucede(sucede(sucede(n)))))))))));
        fin sino inicio
            mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
            este;
            avanza;
            mientras junto-a-zumbador hacer coge-zumbador;
            norte;
            avanza;
            oeste;
            si frente-bloqueado y derecha-bloqueada entonces apagate;
            si no si-es-cero(n)entonces inicio
                repetir precede(n) veces inicio
                    paso;
                fin;
                completa;
            fin sino inicio
                si algun-zumbador-en-la-mochila entonces deja-zumbador;
                completa;
            fin;

        fin;
    fin;
    inicia-ejecucion
        este;
        mientras frente-libre hacer avanza;
        oeste;
        avanza;
        cuenta(0);
        apagate;
    termina-ejecucion
finalizar-programa
