iniciar-programa
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion acomodar como inicio
        oeste;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        este;
        avanza;
        mientras no-junto-a-zumbador y frente-libre hacer inicio
            avanza;
        fin;
    fin;
    define-nueva-instruccion recoger(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            recoger(sucede(n));
        fin sino inicio
            oeste;
            mientras no-junto-a-zumbador hacer inicio
                avanza;
            fin;
            repetir 9 veces inicio
                repetir n veces inicio
                    coge-zumbador;
                fin;
            fin;
            acomodar;
            mientras junto-a-zumbador hacer inicio
                coge-zumbador;
            fin;
        fin;
    fin;
    define-nueva-instruccion verificar como inicio
        si frente-libre entonces inicio
            avanza;
            mientras no-junto-a-zumbador y frente-libre hacer inicio
                avanza;
            fin;
            si junto-a-zumbador entonces inicio
                oeste;
                avanza;
                mientras no-junto-a-zumbador hacer inicio
                    avanza;
                fin;
                este;
                recoger(0);
            fin sino inicio
                oeste;
                mientras no-junto-a-zumbador hacer inicio
                    avanza;
                fin;
                este;
                recoger(0);
            fin;
        fin sino inicio
            si junto-a-zumbador entonces inicio
                mientras junto-a-zumbador hacer inicio
                    coge-zumbador;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion ir1aciento como inicio
        oeste;
        mientras derecha-bloqueada hacer inicio
            si frente-libre entonces inicio
                avanza;
            fin sino inicio
                gira-izquierda;
            fin;
        fin;
        si orientado-al-sur y frente-bloqueado entonces inicio
            si izquierda-bloqueada y derecha-libre entonces inicio
                norte;
                avanza;
                oeste;
            fin;
        fin sino inicio
            oeste;
        fin;
    fin;
    define-nueva-instruccion camina como inicio
        si algun-zumbador-en-la-mochila entonces inicio
            deja-zumbador;
            si frente-libre y algun-zumbador-en-la-mochila entonces inicio
                avanza;
                camina;
            fin sino inicio
                si algun-zumbador-en-la-mochila y frente-bloqueado entonces inicio
                    si orientado-al-oeste entonces inicio
                        norte;
                        si frente-libre entonces inicio
                            avanza;
                            este;
                            camina;
                        fin sino inicio
                            ir1aciento;
                            camina;
                        fin;
                    fin sino inicio
                        norte;
                        si frente-libre entonces inicio
                            avanza;
                            oeste;
                            camina;
                        fin sino inicio
                            ir1aciento;
                            camina;
                        fin;
                    fin;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion sentarse como inicio
        norte;
        si frente-libre y algun-zumbador-en-la-mochila entonces inicio
            avanza;
            oeste;
            camina;
        fin sino inicio
            si derecha-libre entonces inicio
                este;
                mientras frente-libre hacer inicio
                    avanza;
                fin;
                sentarse;
            fin;
        fin;
    fin;
    inicia-ejecucion
        acomodar;
        verificar;
        sentarse;
        apagate;
    termina-ejecucion
finalizar-programa
