iniciar-programa

    define-nueva-instruccion gira(n) como inicio
        repetir n veces gira-izquierda;
    fin;

    define-nueva-instruccion paso como inicio
        si frente-libre entonces inicio
            avanza;
        fin sino inicio
            si orientado-al-oeste entonces inicio
                gira(3);
                si frente-libre entonces inicio
                    avanza;
                    gira(3);
                fin sino inicio
                    gira(2);
                    mientras frente-libre hacer avanza;
                    gira(1);
                    mientras frente-libre hacer avanza;
                    gira(2);
                fin;
            fin sino inicio
                gira(1);
                si frente-libre entonces inicio
                    avanza;
                    gira(1);
                fin sino inicio
                    gira(2);
                    mientras frente-libre hacer avanza;
                    gira(2);
                    avanza;
                    gira(1);
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion cuenta(z) como inicio
        gira(2);
        avanza;
        gira(1);
        avanza;
        gira(1);
        repetir precede(z) veces paso;
    fin;

    define-nueva-instruccion cuenta-decenas(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cuenta-decenas(sucede(sucede(sucede(sucede(sucede(sucede(sucede(sucede(sucede(sucede(n)))))))))));
        fin sino inicio
            cuenta(n);
        fin;
    fin;

    define-nueva-instruccion cuenta-unidades(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cuenta-unidades(sucede(x));
        fin sino inicio
            mientras no-orientado-al-oeste hacer gira(1);
            avanza;
            cuenta-decenas(x);
        fin;
    fin;

    inicia-ejecucion
        mientras no-orientado-al-este hacer gira(1);
        mientras frente-libre hacer avanza;
        cuenta-unidades(0);
        apagate;
    termina-ejecucion
finalizar-programa
