iniciar-programa
    define-nueva-instruccion gira(z) como inicio
        repetir z veces gira-izquierda;
    fin;
    define-nueva-instruccion principio como inicio
        mientras no-orientado-al-sur hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        gira(1);
        mientras frente-libre hacer avanza;
        gira(3);
        mientras frente-libre hacer avanza;
        gira(2);
        avanza;
        gira(1);
    fin;
    define-nueva-instruccion lugar(n) como inicio
        si no si-es-cero(n) entonces inicio
            si frente-libre entonces inicio
                avanza;
                lugar(precede(n));
            fin sino inicio
                si orientado-al-oeste entonces inicio
                    gira(3);
                    si frente-libre entonces inicio
                        avanza;
                        gira(3);
                        lugar(precede(n));
                    fin sino inicio
                        principio;
                        lugar(precede(n));
                    fin;
                fin;
                si orientado-al-este entonces inicio
                    gira(1);
                    si frente-libre entonces inicio
                        avanza;
                        gira(1);
                        lugar(precede(n));
                    fin sino inicio
                        principio;
                        lugar(precede(n));
                    fin;
                fin;
            fin;
        fin sino apagate;
    fin;
    define-nueva-instruccion boleto(n) como inicio
        si junto-a-zumbador y orientado-al-este entonces inicio
            coge-zumbador;
            boleto(sucede(n));
        fin;
        si orientado-al-este entonces inicio
            gira(2);
            avanza;
        fin;
        si junto-a-zumbador y orientado-al-oeste entonces inicio
            coge-zumbador;
            boleto(sucede(sucede(sucede(sucede(sucede(sucede(sucede(sucede(sucede(sucede(n)))))))))));
        fin;
        si no-junto-a-zumbador y orientado-al-oeste entonces inicio
            gira(2);
            avanza;
            gira(1);
            avanza;
            gira(1);
            si frente-bloqueado y derecha-bloqueada entonces apagate sino lugar(precede(n));
        fin;
    fin;
inicia-ejecucion
    mientras no-orientado-al-este hacer gira-izquierda;
    mientras frente-libre hacer avanza;
    boleto(0);
        apagate;
    termina-ejecucion
finalizar-programa
