iniciar-programa
  define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
  define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
  define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
  define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

  define-nueva-instruccion compara(n) como inicio
      si junto-a-zumbador y no si-es-cero (n) entonces inicio
          coge-zumbador;
          compara(precede(n));
          deja-zumbador;
      fin sino inicio
          si no si-es-cero (n) entonces inicio
                  (*ES MENOR EL QUE ESTABA*)

          fin sino inicio
                  (*ES MENOR EL QUE TRAIGO*)
              mientras junto-a-zumbador hacer coge-zumbador;
          fin;
      fin;
  fin;
  define-nueva-instruccion revisa(n) como inicio
      repetir 2 veces coge-zumbador;
      si junto-a-zumbador entonces inicio
          repetir 2 veces deja-zumbador;
          compara(n);
      fin sino inicio
          repetir n veces deja-zumbador;
      fin;
  fin;
  define-nueva-instruccion minimo (n) como inicio
      si junto-a-zumbador entonces inicio
          coge-zumbador;
          si junto-a-zumbador entonces inicio
              deja-zumbador;
              revisa(n);
          fin sino inicio
              deja-zumbador;
          fin;
      fin sino inicio

          deja-zumbador;
          norte;
          si frente-libre entonces inicio
              avanza;
              minimo(sucede(n));
              sur;
              avanza;
          fin;
          sur;
          si frente-libre entonces inicio
              avanza;
              minimo(sucede(n));
              norte;
              avanza;
          fin;
          este;
          si frente-libre entonces inicio
              avanza;
              minimo(sucede(n));
              oeste;
              avanza;
          fin;
          oeste;
          si frente-libre entonces inicio
              avanza;
              minimo(sucede(n));
              este;
              avanza;
          fin;
          coge-zumbador;

      fin;
  fin;
  define-nueva-instruccion localiza como inicio
      si junto-a-zumbador entonces inicio
          coge-zumbador;
          si junto-a-zumbador entonces inicio
              repetir 2 veces coge-zumbador;
              apagate;
          fin sino inicio
              deja-zumbador;
          fin;
      fin sino inicio

          deja-zumbador;
          norte;
          si frente-libre entonces inicio
              avanza;
              localiza;
              sur;
              avanza;
          fin;
          sur;
          si frente-libre entonces inicio
              avanza;
              localiza;
              norte;
              avanza;
          fin;
          este;
          si frente-libre entonces inicio
              avanza;
              localiza;
              oeste;
              avanza;
          fin;
          oeste;
          si frente-libre entonces inicio
              avanza;
              localiza;
              este;
              avanza;
          fin;
      fin;
  fin;
    inicia-ejecucion
        minimo(3);
        localiza;
        apagate;
    termina-ejecucion
finalizar-programa
