iniciar-programa

    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion deja(n) como inicio
        repetir n veces inicio
            deja-zumbador;
        fin;
    fin;

    define-nueva-instruccion compara(n) como inicio
        si junto-a-zumbador y no si-es-cero(n) entonces inicio
            coge-zumbador;
            compara(precede(n));
            deja-zumbador;
        fin sino inicio
            mientras junto-a-zumbador hacer inicio
                coge-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion busquedaExhaustiva(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si no-junto-a-zumbador entonces inicio
                    deja(n); (* Si es la primera vez, lo toma como posible respuesta *)
                fin sino inicio
                    compara(n); (* Compara si es menor que la respuesta actual *)
                fin;
                deja-zumbador;
            fin;
            deja-zumbador;
        fin sino inicio

            deja-zumbador; (* Marcado de visitado *)

            norte;
            si frente-libre entonces inicio
                avanza;
                busquedaExhaustiva(sucede(n));
                sur;
                avanza;
            fin;

            sur;
            si frente-libre entonces inicio
                avanza;
                busquedaExhaustiva(sucede(n));
                norte;
                avanza;
            fin;

            este;
            si frente-libre entonces inicio
                avanza;
                busquedaExhaustiva(sucede(n));
                oeste;
                avanza;
            fin;

            oeste;
            si frente-libre entonces inicio
                avanza;
                busquedaExhaustiva(sucede(n));
                este;
                avanza;
            fin;

            coge-zumbador; (* Desmarca visitado *)
        fin;
    fin;

    define-nueva-instruccion busquedaProfundidad como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                apagate;
            fin;
            deja-zumbador;
        fin sino inicio

            deja-zumbador; (* Marca visitado *)

            norte;
            si frente-libre entonces inicio
                avanza;
                busquedaProfundidad;
                sur;
                avanza;
            fin;

            sur;
            si frente-libre entonces inicio
                avanza;
                busquedaProfundidad;
                norte;
                avanza;
            fin;

            este;
            si frente-libre entonces inicio
                avanza;
                busquedaProfundidad;
                oeste;
                avanza;
            fin;

            oeste;
            si frente-libre entonces inicio
                avanza;
                busquedaProfundidad;
                este;
                avanza;
            fin;
        fin;
    fin;

    inicia-ejecucion
        busquedaExhaustiva(0);
        busquedaProfundidad;
        apagate;
    termina-ejecucion
finalizar-programa
