iniciar-programa
define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

define-nueva-instruccion chico(x) como
    inicio
    si no si-es-cero (x) entonces
        inicio
        si junto-a-zumbador entonces
            inicio
                coge-zumbador;
                chico(precede(x));
                deja-zumbador;
            fin
        fin sino mientras junto-a-zumbador hacer coge-zumbador;
    fin;

define-nueva-instruccion compara(n) como
    inicio
        repetir 2 veces coge-zumbador;
    si junto-a-zumbador entonces
        inicio
            repetir 2 veces deja-zumbador;
            chico(n);
        fin sino repetir n veces deja-zumbador;
    fin;

define-nueva-instruccion mas-corto(n) como
    inicio
    si junto-a-zumbador entonces
        inicio
            coge-zumbador;
        si junto-a-zumbador entonces
            inicio
                deja-zumbador;
                compara(n);
            fin sino deja-zumbador;
        fin
    sino
        inicio
            deja-zumbador;
            norte;
        si frente-libre entonces
            inicio
                avanza;
                mas-corto(sucede(n));
                sur;
                avanza;
            fin;
            sur;
        si frente-libre entonces
            inicio
                avanza;
                mas-corto(sucede(n));
                norte;
                avanza;
            fin;
            este;
        si frente-libre entonces
            inicio
                avanza;
                mas-corto(sucede(n));
                oeste;
                avanza;
            fin;
            oeste;
        si frente-libre entonces
            inicio
                avanza;
                mas-corto(sucede(n));
                este;
                avanza;
            fin;
            coge-zumbador;
        fin;
    fin;

    inicia-ejecucion
        mas-corto(0);
        apagate;
    termina-ejecucion
finalizar-programa
