iniciar-programa
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion comparar(x) como inicio
        si junto-a-zumbador y no si-es-cero(x) entonces inicio
            coge-zumbador;
            comparar(precede(x));
            deja-zumbador;
        fin sino inicio
            si junto-a-zumbador entonces inicio
                mientras junto-a-zumbador hacer inicio
                    coge-zumbador;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion deja(x) como inicio
        repetir x veces deja-zumbador;
    fin;
    define-nueva-instruccion busqueda(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si no junto-a-zumbador entonces inicio
                    deja(x);

                fin sino inicio
                    comparar(x);
                fin;
                    deja-zumbador;
             fin;
             deja-zumbador;
        fin sino inicio
            deja-zumbador;
            norte;
            si frente-libre entonces inicio
                avanza;
                busqueda(sucede(x));
                sur;
                avanza;
            fin;
            sur;
            si frente-libre entonces inicio
                avanza;
                busqueda(sucede(x));
                norte;
                avanza;
            fin;
            este;
            si frente-libre entonces inicio
                avanza;
                busqueda(sucede(x));
                oeste;
                avanza;
            fin;
            oeste;
            si frente-libre entonces inicio
                avanza;
                busqueda(sucede(x));
                este;
                avanza;
            fin;
            coge-zumbador;
        fin;

    fin;
     define-nueva-instruccion quitar como inicio
       si junto-a-zumbador entonces inicio
           coge-zumbador;
           si junto-a-zumbador entonces inicio
               coge-zumbador;
               apagate;
           fin;
           deja-zumbador;
       fin sino inicio
           deja-zumbador;
           norte;
           si frente-libre entonces inicio
               avanza;
               quitar;
               sur;
               avanza;
           fin;
           sur;
           si frente-libre entonces inicio
               avanza;
               quitar;
               norte;
               avanza;
           fin;
           este;
           si frente-libre entonces inicio
               avanza;
               quitar;
               oeste;
               avanza;
           fin;
           oeste;
           si frente-libre entonces inicio
               avanza;
               quitar;
               este;
               avanza;
           fin;
        fin;
     fin;



    inicia-ejecucion
        busqueda(0);
        quitar;
        apagate;
    termina-ejecucion
finalizar-programa
