iniciar-programa
(*busqueda de el 2 probando con 1, con 2, con 3,etc hasta llegar a el *)
define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
define-nueva-instruccion busca(n) como inicio
    si no si-es-cero(n) entonces inicio
        si no-junto-a-zumbador y no-orientado-al-sur entonces inicio
            deja-zumbador;
            norte;
            si frente-libre entonces inicio
                avanza;
                busca(precede(n));
                si no-orientado-al-sur entonces inicio
                    sur;
                    avanza;
                    norte;
                fin sino inicio
                    deja-zumbador;
                fin;
            fin;
            si no-orientado-al-sur entonces inicio
                este;
                si frente-libre entonces inicio
                    avanza;
                    busca(precede(n));
                    si no-orientado-al-sur entonces inicio
                        oeste;
                        avanza;
                    fin sino inicio
                        deja-zumbador;
                    fin;
                fin;
            fin;
            si no-orientado-al-sur entonces inicio
                sur;
                si frente-libre entonces inicio
                    avanza;
                    este;
                    busca(precede(n));
                    si orientado-al-este entonces inicio
                        norte;
                        avanza;
                    fin sino inicio
                        si orientado-al-sur entonces inicio
                            deja-zumbador;
                        fin sino inicio
                            norte;
                            avanza;
                        fin;
                    fin;
                fin sino inicio
                    este;
                fin;
            fin;
            si no-orientado-al-sur entonces inicio
                oeste;
                si frente-libre entonces inicio
                    avanza;
                    busca(precede(n));
                    si no-orientado-al-sur entonces inicio
                        este;
                        avanza;
                    fin sino inicio
                        deja-zumbador;
                    fin;
                fin;
            fin;
            si no-orientado-al-sur entonces coge-zumbador;
        fin;
    fin sino inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                sur;
            fin sino inicio
                deja-zumbador;
            fin;
        fin;
    fin;
fin;
define-nueva-instruccion infinito(n) como inicio
    si no-orientado-al-sur entonces inicio
        busca(n);
        infinito(sucede(n));
    fin sino inicio
        apagate;
    fin;
fin;
    inicia-ejecucion
    si junto-a-zumbador entonces inicio
        repetir 2 veces coge-zumbador;
        apagate;
    fin;
    norte;
    infinito(1);
        apagate;
    termina-ejecucion
finalizar-programa
