iniciar-programa
    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierdA;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierdA;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierdA;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierdA;
    define-nueva-instruccion compara(n) como inicio
        si junto-a-zumbador y no si-es-cero(n) entonces inicio
            coge-zumbador;
            compara(precede(n));
            deja-zumbador;
        fin sino inicio
            si junto-a-zumbador entonces
                mientras junto-a-zumbador hacer coge-zumbador;
        fin;
    fin;
    define-nueva-instruccion busqueda(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si no junto-a-zumbador entonces inicio
                    repetir n veces deja-zumbador;
                fin sino inicio
                    compara(n);
                fin;
                deja-zumbador;
            fin;
            deja-zumbador;
        fin sino inicio
            deja-zumbador;
            norte;
            si frente-libre entonces inicio
                avanza;
                busqueda(sucede(n));
                sur;
                avanza;
            fin;
            sur;
            si frente-libre entonces inicio
                avanza;
                busqueda(sucede(n));
                norte;
                avanza;
            fin;
            este;
            si frente-libre entonces inicio
                avanza;
                busqueda(sucede(n));
                oeste;
                avanza;
            fin;
            oeste;
            si frente-libre entonces inicio
                avanza;
                busqueda(sucede(n));
                este;
                avanza;
            fin;
            coge-zumbador;
        fin;
    fin;
    define-nueva-instruccion busquedaa como inicio
          si junto-a-zumbador entonces inicio
              coge-zumbador;
              si junto-a-zumbador entonces inicio
                  coge-zumbador;
                  apagate;
              fin sino deja-zumbador;
          fin sino inicio
          deja-zumbador;
          norte;
            si frente-libre entonces inicio
                avanza;
                busquedaa;
                sur;
                avanza;
            fin;
            sur;
            si frente-libre entonces inicio
                avanza;
                busquedaa;
                norte;
                avanza;
            fin;
            este;
            si frente-libre entonces inicio
                avanza;
                busquedaa;
                oeste;
                avanza;
            fin;
            oeste;
            si frente-libre entonces inicio
                avanza;
                busquedaa;
                este;
                avanza;
            fin;
            coge-zumbador;
        fin;
    fin;
    inicia-ejecucion
         busqueda(0);
         busquedaa;
         apagate;
    termina-ejecucion
finalizar-programa
