iniciar-programa
    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion busqueda(n) como inicio
        si no si-es-cero(n) y no orientado-al-sur entonces inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                    sur;
                fin sino inicio
                    deja-zumbador;
                fin;
            fin sino inicio
                deja-zumbador;
                si no orientado-al-sur entonces inicio
                    norte;
                    si frente-libre entonces inicio
                        avanza;
                        busqueda(precede(n));
                        si no orientado-al-sur entonces inicio
                            sur;
                            avanza;
                            norte;
                        fin;
                    fin;
                fin;
                si no orientado-al-sur entonces inicio
                    sur;
                    si frente-libre entonces inicio
                        avanza;
                        norte;
                        busqueda(precede(n));
                        si no orientado-al-sur entonces inicio
                            norte;
                            avanza;
                        fin;
                    fin sino inicio
                        norte;
                    fin;
                fin;
                si no orientado-al-sur entonces inicio
                    este;
                    si frente-libre entonces inicio
                        avanza;
                        busqueda(precede(n));
                        si no orientado-al-sur entonces inicio
                            oeste;
                            avanza;
                        fin;
                    fin;
                fin;
                si no orientado-al-sur entonces inicio
                    oeste;
                    si frente-libre entonces inicio
                        avanza;
                        busqueda(precede(n));
                        si no orientado-al-sur entonces inicio
                            este;
                            avanza;
                        fin;
                    fin;
                fin;
                si no orientado-al-sur entonces coge-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion infinito(n) como inicio
        si no-orientado-al-sur entonces inicio
            busqueda(n);
            infinito(sucede(n));
        fin sino inicio
            repetir n veces deja-zumbador;
            repetir 2 veces coge-zumbador;
        fin;
    fin;

    inicia-ejecucion
        norte;
        infinito(1);
        apagate;
    termina-ejecucion
finalizar-programa
