iniciar-programa

    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion deja(k) como inicio
        repetir k veces inicio
            deja-zumbador;
        fin;
    fin;

    define-nueva-instruccion pon(n) como inicio
        mientras junto-a-zumbador hacer inicio
            coge-zumbador;
        fin;
        deja(n);
    fin;

    define-nueva-instruccion compara(k) como inicio
        si junto-a-zumbador y no si-es-cero(k) entonces inicio
            coge-zumbador;
            compara(precede(k));
            deja-zumbador;
        fin sino inicio
            si junto-a-zumbador entonces inicio (*k es menor*)
                sur;
            fin sino inicio     (*k es mayor*)
                norte;
            fin;
        fin;
    fin;

    define-nueva-instruccion busqueda(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si no-junto-a-zumbador entonces inicio (*es la primera vez que llegamos*)
                    deja(sucede(sucede(n))); (*dejo el total de calorias + 2*)
                fin sino inicio
                    deja(2);
                fin;
                compara(sucede(sucede(n))); (*esta comparacion es inutil la primera vez*)
                si orientado-al-sur entonces inicio
                    pon(sucede(sucede(n)));
                fin;
            fin sino inicio
                deja-zumbador;
            fin;
        fin sino inicio
            deja-zumbador;
            norte;
            si frente-libre entonces inicio
                avanza;
                busqueda(sucede (n));
                sur;
                avanza;
            fin;

            sur;
            si frente-libre entonces inicio
                avanza;
                busqueda(sucede (n));
                norte;
                avanza;
            fin;

            este;
            si frente-libre entonces inicio
                avanza;
                busqueda(sucede (n));
                oeste;
                avanza;
            fin;

            oeste;
            si frente-libre entonces inicio
                avanza;
                busqueda(sucede (n));
                este;
                avanza;
            fin;

            coge-zumbador;
        fin;
    fin;

    define-nueva-instruccion quitar2 como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                apagate;
            fin;
            deja-zumbador;
        fin sino inicio
            deja-zumbador;
            norte;
            si frente-libre entonces inicio
                avanza;
                quitar2;
                sur;
                avanza;
            fin;
            sur;
            si frente-libre entonces inicio
                avanza;
                quitar2;
                norte;
                avanza;
            fin;
            este;
            si frente-libre entonces inicio
                avanza;
                quitar2;
                oeste;
                avanza;
            fin;
            oeste;
            si frente-libre entonces inicio
                avanza;
                quitar2;
                este;
                avanza;
            fin;
        fin;
    fin;

    inicia-ejecucion
        busqueda(0);
        quitar2;
        apagate;
    termina-ejecucion
finalizar-programa

