iniciar-programa
define-nueva-instruccion norte como
    mientras no orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como
    mientras no orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como
    mientras no orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como
    mientras no orientado-al-oeste hacer gira-izquierda;

define-nueva-instruccion comparar(a) como inicio
    si junto-a-zumbador y no si-es-cero(a) entonces inicio
        coge-zumbador;
        comparar(precede(a));
        deja-zumbador;
    fin sino inicio
        si junto-a-zumbador y si-es-cero(a) entonces inicio
            mientras junto-a-zumbador hacer coge-zumbador;
        fin;
    fin;
fin;

define-nueva-instruccion caloria(a) como inicio
    si no junto-a-zumbador entonces inicio
        deja-zumbador;
        norte;
        si frente-libre entonces inicio
            avanza;
            caloria(sucede(a));
            sur;
            avanza;
        fin;
        sur;
        si frente-libre entonces inicio
            avanza;
            caloria(sucede(a));
            norte;
            avanza;
        fin;
        este;
        si frente-libre entonces inicio
            avanza;
            caloria(sucede(a));
            oeste;
            avanza;
        fin;
        oeste;
        si frente-libre entonces inicio
            avanza;
            caloria(sucede(a));
            este;
            avanza;
        fin;
        coge-zumbador;
    fin sino inicio
        coge-zumbador;
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                repetir 2 veces deja-zumbador;
                comparar(a);
            fin sino inicio
                repetir a veces deja-zumbador;
            fin;
        fin sino inicio
            deja-zumbador;
        fin;
    fin;
fin;

    inicia-ejecucion
        caloria(0);

        apagate;
    termina-ejecucion
finalizar-programa
