iniciar-programa

    define-nueva-instruccion gira(x) como inicio
        repetir x veces gira-izquierda;
    fin;

    define-nueva-instruccion compara(x) como inicio
        si (junto-a-zumbador y no si-es-cero(x)) entonces inicio
            coge-zumbador;
            compara(precede(x));
            deja-zumbador;
        fin sino inicio
            mientras junto-a-zumbador hacer coge-zumbador;
        fin;
    fin;

    define-nueva-instruccion busca(a) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    compara(a);
                fin sino inicio
                    repetir a veces deja-zumbador;
                fin;
                deja-zumbador;
            fin;
            deja-zumbador;
        fin sino inicio
            deja-zumbador;
            mientras no-orientado-al-norte hacer gira-izquierda;
            si frente-libre entonces inicio
                avanza;
                busca(sucede(a));
                 mientras no-orientado-al-sur hacer gira-izquierda;
                 avanza;
            fin;
            mientras no-orientado-al-este hacer gira-izquierda;
            si frente-libre entonces inicio
                avanza;
                busca(sucede(a));
                 mientras no-orientado-al-oeste hacer gira-izquierda;
                 avanza;
            fin;
            mientras no-orientado-al-oeste hacer gira-izquierda;
            si frente-libre entonces inicio
                avanza;
                busca(sucede(a));
                 mientras no-orientado-al-este hacer gira-izquierda;
                 avanza;
            fin;
            mientras no-orientado-al-sur hacer gira-izquierda;
            si frente-libre entonces inicio
                avanza;
                busca(sucede(a));
                 mientras no-orientado-al-norte hacer gira-izquierda;
                 avanza;
            fin;
            coge-zumbador;
        fin;
    fin;

    define-nueva-instruccion buscaresultado como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                apagate;
            fin;
            deja-zumbador;
        fin sino inicio
            deja-zumbador;
            mientras no-orientado-al-norte hacer gira-izquierda;
            si frente-libre entonces inicio             
                avanza;
                buscaresultado;
                mientras no-orientado-al-sur hacer gira-izquierda;
                avanza;
            fin;
            mientras no-orientado-al-sur hacer gira-izquierda;
            si frente-libre entonces inicio
                avanza;
                buscaresultado;
                mientras no-orientado-al-norte hacer gira-izquierda;
                avanza;
            fin;
            mientras no-orientado-al-este hacer gira-izquierda;
            si frente-libre entonces inicio
                avanza;
                buscaresultado;
                mientras no-orientado-al-oeste hacer gira-izquierda;
                avanza;
            fin;
            mientras no-orientado-al-oeste hacer gira-izquierda;
            si frente-libre entonces inicio
                avanza;
                buscaresultado;
                mientras no-orientado-al-este hacer gira-izquierda;
                avanza;
            fin;
        fin;
    fin;
    inicia-ejecucion
        busca(0);
        buscaresultado;
        apagate;
    termina-ejecucion
finalizar-programa
