iniciar-programa
    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;

    define-nueva-instruccion menor(n) como inicio
        si junto-a-zumbador y no si-es-cero(n) entonces inicio
            coge-zumbador;
            menor(precede(n));
        fin sino inicio
            si si-es-cero(n) entonces inicio
                mientras junto-a-zumbador hacer inicio
                    coge-zumbador;
                fin;
            fin sino inicio
                repetir n veces inicio
                    deja-zumbador;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion menor2(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            menor2(n);
            coge-zumbador;
        fin sino inicio
            repetir n veces inicio
                deja-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion buscar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    menor(n);
                    si junto-a-zumbador entonces inicio
                        menor2(n);
                    fin sino inicio
                        repetir n veces inicio
                            deja-zumbador;
                        fin;
                    fin;
                fin sino inicio
                    repetir n veces inicio
                        deja-zumbador;
                    fin;
                fin;
                deja-zumbador;
                deja-zumbador;
            fin sino inicio
                deja-zumbador;
            fin;
        fin sino inicio
            deja-zumbador;
            norte;
            si frente-libre entonces inicio
                avanza;
                buscar(sucede(n));
                sur;
                avanza;
            fin;
            este;
            si frente-libre entonces inicio
                avanza;
                buscar(sucede(n));
                oeste;
                avanza;
            fin;
            sur;
            si frente-libre entonces inicio
                avanza;
                buscar(sucede(n));
                norte;
                avanza;
            fin;
            oeste;
            si frente-libre entonces inicio
                avanza;
                buscar(sucede(n));
                este;
                avanza;
            fin;
            coge-zumbador;
        fin;
    fin;

    define-nueva-instruccion quitar como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                apagate;
            fin sino inicio
                deja-zumbador;
            fin;
        fin sino inicio
            deja-zumbador;
            norte;
            si frente-libre entonces inicio
                avanza;
                quitar;
                sur;
                avanza;
            fin;
            este;
            si frente-libre entonces inicio
                avanza;
                quitar;
                oeste;
                avanza;
            fin;
            sur;
            si frente-libre entonces inicio
                avanza;
                quitar;
                norte;
                avanza;
            fin;
            oeste;
            si frente-libre entonces inicio
                avanza;
                quitar;
                este;
                avanza;
            fin;
        fin;
    fin;

    inicia-ejecucion
        buscar(0);
        quitar;
        apagate;
    termina-ejecucion
finalizar-programa
