iniciar-programa
    define-nueva-instruccion gira(n) como inicio
        repetir n veces
            gira-izquierda;
    fin;
    define-nueva-instruccion norte como inicio
       mientras no-orientado-al-norte hacer
          gira-izquierda;
    fin;
    define-nueva-instruccion este como inicio
       mientras no-orientado-al-este hacer
          gira-izquierda;
    fin;
    define-nueva-instruccion oeste como inicio
       mientras no-orientado-al-oeste hacer
          gira-izquierda;
    fin;
    define-nueva-instruccion sur como inicio
       mientras no-orientado-al-sur hacer
          gira-izquierda;
    fin;
    define-nueva-instruccion compara(n) como inicio
        si si-es-cero(n) entonces inicio
            mientras junto-a-zumbador hacer
                coge-zumbador;
        fin sino inicio
            si  junto-a-zumbador entonces inicio
            coge-zumbador;
            compara(precede(n));
            deja-zumbador;
            fin;
        fin;
    fin;
    define-nueva-instruccion busca(n) como inicio
         si junto-a-zumbador entonces inicio
           coge-zumbador;
           si junto-a-zumbador entonces inicio
               coge-zumbador;
               si junto-a-zumbador entonces inicio
                   compara(n);
               fin
               sino inicio
                   repetir n veces
                       deja-zumbador;
               fin;
               deja-zumbador;
           fin;
           deja-zumbador;
       fin
        sino inicio
           norte;
           si frente-libre entonces inicio
              si no-junto-a-zumbador entonces
                 deja-zumbador;
              avanza;
              busca(sucede(n));
              sur;
              si frente-libre entonces
                 avanza;
           fin;
           este;
           si frente-libre entonces inicio
              si no-junto-a-zumbador entonces
                 deja-zumbador;
              avanza;
              busca(sucede(n));
              oeste;
              si frente-libre entonces
                 avanza;
           fin;
           sur;
           si frente-libre entonces inicio
              si no-junto-a-zumbador entonces
                 deja-zumbador;
              avanza;
              busca(sucede(n));
              norte;
              si frente-libre entonces
                 avanza;
           fin;
           oeste;
           si frente-libre entonces inicio
              si no-junto-a-zumbador entonces
                 deja-zumbador;
                 avanza;
              busca(sucede(n));
              este;
              si frente-libre entonces
                 avanza;
           fin;
           si junto-a-zumbador entonces
           coge-zumbador;
        fin;
    fin;
    define-nueva-instruccion dos como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                apagate;
            fin sino inicio
                deja-zumbador;
            fin;
        fin
        sino inicio
            deja-zumbador;
            norte;
            si frente-libre entonces inicio
                avanza;
                dos;
                sur;
                avanza;
            fin;
            este;
            si frente-libre entonces inicio
                avanza;
                dos;
                oeste;
                avanza;
            fin;
            sur;
            si frente-libre entonces inicio
                avanza;
                dos;
                norte;
                avanza;
            fin;
            oeste;
            si frente-libre entonces inicio
                avanza;
                dos;
                este;
                avanza;
            fin;
        fin;
    fin;
    inicia-ejecucion
            busca(0);
            dos;
        apagate;
    termina-ejecucion
finalizar-programa