iniciar-programa

define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;

    define-nueva-instruccion compara(x) como inicio
        si junto-a-zumbador y no si-es-cero(x) entonces inicio
            coge-zumbador;
            compara(precede(x));
            deja-zumbador;
        fin sino inicio
            mientras junto-a-zumbador hacer inicio
                coge-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion busca(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    compara(x);
                fin sino inicio
                    repetir x veces deja-zumbador;
                fin;
                repetir 2 veces deja-zumbador;
            fin sino inicio
                deja-zumbador;
            fin;
        fin sino inicio

            deja-zumbador;

            norte;
            si frente-libre entonces inicio
                avanza;
                busca(sucede(x));
                sur;
                avanza;
            fin;

            sur;
            si frente-libre entonces inicio
                avanza;
                busca(sucede(x));
                norte;
                avanza;
            fin;

            este;
            si frente-libre entonces inicio
                avanza;
                busca(sucede(x));
                oeste;
                avanza;
            fin;

            oeste;
            si frente-libre entonces inicio
                avanza;
                busca(sucede(x));
                este;
                avanza;
            fin;

            coge-zumbador;
        fin;
    fin;

    define-nueva-instruccion quita como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                apagate;
            fin sino inicio
                deja-zumbador;
            fin;
        fin sino inicio
            deja-zumbador;

            norte;
            si frente-libre entonces inicio
                avanza;
                quita;
                sur;
                avanza;
            fin;

            este;
            si frente-libre entonces inicio
                avanza;
                quita;
                oeste;
                avanza;
            fin;

            oeste;
            si frente-libre entonces inicio
                avanza;
                quita;
                este;
                avanza;
            fin;

            sur;
            si frente-libre entonces inicio
                avanza;
                quita;
                norte;
                avanza;
            fin;

        fin;
    fin;

    inicia-ejecucion
        busca(0);
        quita;
        apagate;
    termina-ejecucion
finalizar-programa