iniciar-programa
define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

define-nueva-instruccion salida como
    inicio
        este;
    mientras frente-libre hacer avanza;
        norte;
    mientras frente-libre hacer avanza;
    fin;

define-nueva-instruccion busqueda como
    inicio
    si no-junto-a-zumbador entonces
        inicio
            deja-zumbador;
            oeste;
        si frente-libre entonces
            inicio
                avanza;
                busqueda;
                este;
                avanza;
            fin;
            sur;
        si frente-libre entonces
            inicio
                avanza;
                busqueda;
                norte;
                avanza;
            fin;
        fin;
    fin;

define-nueva-instruccion esquina como
    inicio
        sur;
    mientras frente-libre hacer avanza;
        este;
    mientras frente-libre hacer avanza;
    fin;

define-nueva-instruccion camina como
    inicio
    si frente-libre entonces
        inicio
            avanza;
        fin
    sino
        inicio
            este;
        mientras frente-libre hacer avanza;
            norte;
        si frente-libre entonces
            inicio
                avanza;
                oeste;
            fin;
        fin;
    fin;

define-nueva-instruccion resultado (x) como
    inicio
    si junto-a-zumbador entonces
        inicio
            coge-zumbador;
        si no-junto-a-zumbador entonces
            inicio
                resultado(sucede(x));
            fin
        sino
            inicio
                deja-zumbador;
                camina;
                resultado(x);
            fin;
        fin
    sino
        inicio
        mientras no-junto-a-zumbador y no-orientado-al-norte hacer camina;
        si junto-a-zumbador entonces resultado (x)
        sino
            inicio
                repetir x veces deja-zumbador;
                apagate;
            fin;
        fin;
    fin;

define-nueva-instruccion cochecito como
    inicio
        salida;
    si junto-a-zumbador entonces
        inicio
        mientras junto-a-zumbador hacer coge-zumbador;
        apagate;
        fin;
        busqueda;
        esquina;
        oeste;
        resultado(0);
    fin;

    inicia-ejecucion
        cochecito;
        apagate;
    termina-ejecucion
finalizar-programa
