iniciar-programa
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

define-nueva-instruccion coche(n) como inicio
    si no-junto-a-zumbador entonces deja-zumbador;
    sur;
    si frente-libre entonces inicio
        avanza;
        si no-junto-a-zumbador entonces coche(sucede(n));
        norte;
        avanza;
    fin;
    oeste;
    si frente-libre entonces inicio
        avanza;
        si no-junto-a-zumbador entonces coche(sucede(n));
        este;
        avanza;
    fin;
fin;

define-nueva-instruccion mide(n) como inicio
    mientras orientado-al-este hacer inicio
        mientras no-junto-a-zumbador hacer inicio
            si frente-libre entonces inicio
                avanza;
            fin sino inicio
                norte;
                si frente-libre entonces inicio
                    avanza;
                    oeste;
                    mientras frente-libre hacer avanza;
                    este;
                fin sino inicio
                    mientras junto-a-zumbador hacer coge-zumbador;
                    repetir n veces deja-zumbador;
                    apagate;
                fin;
            fin;
        fin;
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                si frente-libre entonces inicio
                    avanza;
                fin sino inicio
                    norte;
                    si frente-libre entonces inicio
                        avanza;
                        oeste;
                        mientras frente-libre hacer avanza;
                        este;
                    fin sino inicio
                        mientras junto-a-zumbador hacer coge-zumbador;
                        repetir n veces deja-zumbador;
                        apagate;
                    fin;
                fin;
            fin sino inicio
                mide(sucede(n));
            fin;
        fin;
    fin;
fin;

    inicia-ejecucion
    norte;
    mientras frente-libre hacer avanza;
    este;
    mientras frente-libre hacer avanza;
    coche(0);
    oeste;
    mientras frente-libre hacer avanza;
    sur;
    mientras frente-libre hacer avanza;
    este;
    mide(0);
        apagate;
    termina-ejecucion
finalizar-programa
