iniciar-programa
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion avanzar como mientras frente-libre hacer avanza;
define-nueva-instruccion ve2 como inicio
    norte;
    si frente-libre entonces inicio
        avanza;
        ve2;
        sur;
        avanza;
    fin sino inicio
        deja-zumbador;
    fin;
fin;
define-nueva-instruccion ve como inicio
    este;
    si frente-libre entonces inicio
        avanza;
        ve;
        oeste;
        avanza;
    fin sino inicio
        ve2;
    fin;
fin;
define-nueva-instruccion busca como inicio
    deja-zumbador;
    ve;
    oeste;
    si frente-libre entonces inicio
        avanza;
        si no-junto-a-zumbador entonces inicio
            busca;
        fin;
        este;
        avanza;
    fin;
    sur;
    si frente-libre entonces inicio
        avanza;
        si no-junto-a-zumbador entonces inicio
            busca;
        fin;
        norte;
        avanza;
    fin;
    norte;
fin;
    inicia-ejecucion
    norte;
    avanzar;
    este;
    avanzar;
    si junto-a-zumbador entonces inicio
    mientras junto-a-zumbador hacer coge-zumbador;
    apagate;
    fin;
    busca;
    coge-zumbador;
        apagate;
    termina-ejecucion
finalizar-programa
