iniciar-programa
define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;

define-nueva-instruccion irfin como
  inicio
    norte;
    mientras frente-libre hacer avanza;
    este;
    mientras frente-libre hacer avanza;
    oeste;
  fin;

define-nueva-instruccion ir11 como
  inicio
    sur;
    mientras frente-libre hacer avanza;
    oeste;
    mientras frente-libre hacer avanza;
    este;
  fin;

define-nueva-instruccion buscar como
  inicio
    si no junto-a-zumbador entonces
      inicio
        deja-zumbador;
        sur;
        si frente-libre entonces
          inicio
            avanza;
            buscar;
            norte;
            avanza;
          fin;

        oeste;
        si frente-libre entonces
          inicio
            avanza;
            buscar;
            este;
            avanza;
          fin;
      fin;
  fin;

 define-nueva-instruccion camina como
   inicio
     este;
     si frente-libre entonces avanza  sino
       inicio
         oeste;
         mientras frente-libre hacer avanza;
         norte;
          si frente-libre entonces
            inicio
              avanza;
              este;
            fin
          sino sur;
       fin;
   fin;

 define-nueva-instruccion recoger(n) como
   inicio
     si no orientado-al-sur entonces
       inicio
         si junto-a-zumbador entonces
           inicio
             coge-zumbador;
             si no junto-a-zumbador entonces
               inicio
                 camina;
                recoger(sucede(n));
              fin  sino
               inicio
                camina;
                recoger(n);
               fin;
           fin
          sino
           inicio
            camina;
            recoger(n);
           fin;
       fin
     sino
       inicio
         irfin;
         mientras junto-a-zumbador hacer coge-zumbador;
         repetir n veces deja-zumbador;
       fin;
   fin;
    inicia-ejecucion
         irfin;
         buscar;
         ir11;
         recoger(0);
        apagate;
    termina-ejecucion
finalizar-programa
