iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;

    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;

    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;

    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion gira(n) como inicio
        repetir n veces gira-izquierda;
    fin;

    define-nueva-instruccion esquina como inicio
        norte;
        mientras frente-libre hacer avanza;
        este;
        mientras frente-libre hacer avanza;
        sur;
    fin;

    define-nueva-instruccion llega11 como inicio
        sur;
        mientras frente-libre hacer avanza;
        oeste;
        mientras frente-libre hacer avanza;
        este;
    fin;

    define-nueva-instruccion busqueda como inicio
        si no-junto-a-zumbador entonces inicio
            deja-zumbador;

            sur;
            si frente-libre entonces inicio
                avanza;
                busqueda;
                norte;
                avanza;
            fin;

            oeste;
            si frente-libre entonces inicio
                avanza;
                busqueda;
                este;
                avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion paso como inicio
        si frente-libre entonces inicio
            avanza;
        fin sino inicio
            norte;
            si frente-libre entonces inicio
                avanza;
                si derecha-bloqueada entonces inicio
                    gira(1);
                fin sino inicio
                    gira(3);
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion recorre(n) como inicio
        si frente-libre o no-orientado-al-norte entonces inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si no-junto-a-zumbador entonces inicio
                    paso;
                    recorre(sucede(n));
                fin sino inicio
                    paso;
                    recorre(n);
                fin;
            fin sino inicio
                paso;
                recorre(n);
            fin;
        fin sino inicio
            esquina;
            mientras junto-a-zumbador hacer coge-zumbador;
            repetir n veces deja-zumbador;
            apagate;
        fin;
    fin;

    inicia-ejecucion
        esquina;
        busqueda;
        llega11;
        recorre(0);
        apagate;
    termina-ejecucion
finalizar-programa
