iniciar-programa
define-nueva-instruccion gira(q) como repetir q veces gira-izquierda;
define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira(1);
define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira(1);
define-nueva-instruccion este como mientras no orientado-al-este hacer gira(1);
define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira(1);
define-nueva-instruccion busqueda como inicio
    si no junto-a-zumbador entonces inicio
        deja-zumbador;
        busqueda;
        fin sino inicio
            sur;
            si frente-libre entonces inicio
                avanza;
                si junto-a-zumbador entonces inicio
                    norte;
                    avanza;
                    sur;
                    fin sino inicio
                        busqueda;
                        norte;
                        avanza;
                        sur;
                        fin;
                fin;
            oeste;
            si frente-libre entonces inicio
                avanza;
                si junto-a-zumbador entonces inicio
                    este;
                    avanza;
                    oeste;
                    fin sino inicio
                        busqueda;
                        este;
                        avanza;
                        oeste;
                        fin;
                fin;
            fin;
    fin;

    define-nueva-instruccion recoger como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                recoger;
                fin sino inicio
                    recoger;
                    deja-zumbador;
                    fin;
            fin sino inicio
                si frente-libre entonces inicio
                    avanza;
                    recoger;
                    fin sino inicio
                        gira(1);
                        si frente-libre entonces inicio
                            avanza;
                            gira(1);
                            mientras frente-libre hacer avanza;
                            oeste;
                            recoger;
                            fin sino inicio
                                este;
                                mientras frente-libre hacer avanza;
                                norte;
                                mientras frente-libre hacer avanza;
                                fin;
                        fin;
                fin;
        fin;
    inicia-ejecucion
    norte;
    mientras frente-libre hacer avanza;
    este;
    mientras frente-libre hacer avanza;
    sur;
    si no junto-a-zumbador entonces inicio
        busqueda;
        oeste;
        recoger;
        fin sino inicio
            mientras junto-a-zumbador hacer coge-zumbador;
            fin;
        apagate;
    termina-ejecucion
finalizar-programa
