iniciar-programa
    define-nueva-instruccion gira(n) como inicio
        repetir n veces
            gira-izquierda;
    fin;
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer
            gira(1);
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer
            gira(1);
    fin;
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer
            gira(1);
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer
            gira(1);
    fin;
    define-nueva-instruccion final(n) como inicio
        si no-orientado-al-norte entonces inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    deja-zumbador;
                    si frente-libre entonces inicio
                        avanza;
                        final(n);
                    fin
                    sino inicio
                        norte;
                        si frente-libre entonces inicio
                            avanza;
                            oeste;
                            mientras frente-libre hacer
                                avanza;
                            este;
                            final(n);
                        fin
                        sino inicio
                            mientras junto-a-zumbador hacer
                                coge-zumbador;
                            repetir n veces
                                deja-zumbador;
                            apagate;
                        fin;
                    fin;
                fin
                sino inicio
                    si frente-libre entonces inicio
                        avanza;
                        final(sucede(n));
                    fin
                    sino inicio
                        norte;
                        si frente-libre entonces inicio
                            avanza;
                            oeste;
                            mientras frente-libre hacer
                                avanza;
                            este;
                            final(sucede(n));
                        fin
                        sino inicio
                            mientras junto-a-zumbador hacer
                                coge-zumbador;
                            repetir sucede(n) veces
                                deja-zumbador;
                            apagate;
                        fin;
                    fin;
                fin;
            fin
            sino inicio
                si frente-libre entonces inicio
                   avanza;
                   final(n);
                fin
                sino inicio
                    norte;
                    si frente-libre entonces inicio
                       avanza;
                       oeste;
                       mientras frente-libre hacer
                          avanza;
                       este;
                       final(n);
                    fin
                    sino inicio
                        mientras junto-a-zumbador hacer
                            coge-zumbador;
                        repetir n veces
                            deja-zumbador;
                        apagate;
                    fin;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion ajuste como inicio
        oeste;
        si frente-libre entonces inicio
           avanza;
        fin
        sino inicio
            sur;
            si frente-libre entonces inicio
               avanza;
               este;
               mientras frente-libre hacer
                  avanza;
            fin
            sino inicio
                este;
                final(0);
            fin;
        fin;
    fin;
    define-nueva-instruccion busca como inicio
        si no-junto-a-zumbador entonces inicio
            si orientado-al-norte y frente-bloqueado y derecha-bloqueada entonces inicio
                deja-zumbador;
                oeste;
                si frente-libre entonces inicio
                    avanza;
                    norte;
                    busca;
                fin
                sino inicio
                    sur;
                    si frente-libre entonces inicio
                        avanza;
                        norte;
                        busca;
                    fin;
                fin;
            fin;
            norte;
            si frente-libre entonces inicio
                avanza;
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                    si junto-a-zumbador entonces inicio
                        deja-zumbador;
                        sur;
                        avanza;
                    fin
                    sino inicio
                        deja-zumbador;
                        sur;
                        avanza;
                        deja-zumbador;
                        ajuste;
                        busca;
                    fin;
                fin
                sino inicio
                    sur;
                    avanza;
                fin;
            fin;
            este;
            si frente-libre entonces inicio
                avanza;
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                    si junto-a-zumbador entonces inicio
                        deja-zumbador;
                        oeste;
                        avanza;
                        ajuste;
                        busca;
                    fin
                    sino inicio
                        deja-zumbador;
                        oeste;
                        avanza;
                        deja-zumbador;
                        ajuste;
                        busca;
                    fin;
                fin
                sino inicio
                    oeste;
                    avanza;
                    ajuste;
                    busca;
                fin;
            fin
            sino inicio
                ajuste;
                busca;
            fin;
        fin
        sino inicio
            ajuste;
            busca;
        fin;
    fin;
    define-nueva-instruccion orienta como inicio
        norte;
        mientras frente-libre hacer
            avanza;
        este;
        mientras frente-libre hacer
            avanza;
        si junto-a-zumbador entonces inicio
            mientras junto-a-zumbador hacer
                coge-zumbador;
            apagate;
        fin
        sino inicio
            norte;
            busca;
        fin;
    fin;
    inicia-ejecucion
        orienta;
        apagate;
    termina-ejecucion
finalizar-programa