iniciar-programa

define-nueva-instruccion gira(z) como repetir z veces gira-izquierda;

define-nueva-instruccion checar_derecha como inicio
    si frente-libre entonces inicio
        avanza;
        si junto-a-zumbador entonces inicio
            gira(2);
            avanza;
            repetir 2 veces deja-zumbador;
        fin sino inicio
            gira(2);
            avanza;
        fin;
    fin;
    si no-orientado-al-oeste entonces gira(2);
fin;

define-nueva-instruccion checar_arriba como inicio
    avanza;
    si junto-a-zumbador entonces inicio
        gira(2);
        avanza;
        repetir 2 veces deja-zumbador;
    fin sino inicio
        gira(2);
        avanza;
    fin;
    gira(3);
fin;

define-nueva-instruccion marcar como inicio
    mientras orientado-al-oeste hacer inicio
        si no-junto-a-zumbador entonces inicio
            si derecha-bloqueada entonces inicio
                gira(2);
                checar_derecha;
            fin sino inicio
                gira(2);
                si frente-bloqueado entonces repetir 2 veces deja-zumbador;
                checar_derecha;
                gira(3);
                checar_arriba;
                repetir 2 veces si junto-a-zumbador entonces coge-zumbador;
            fin;
        fin;
        si frente-libre entonces inicio avanza;
        fin sino inicio
            si izquierda-libre entonces inicio
                gira(2);
                mientras frente-libre hacer avanza;
                gira(3);
                avanza;
                gira(3);
            fin sino gira(2);
        fin;
    fin;
fin;

define-nueva-instruccion contar(a) como inicio
    si frente-libre entonces inicio
        si junto-a-zumbador entonces inicio
            avanza;
            contar(a);
        fin sino inicio
            avanza;
            contar(sucede(a));
        fin;
    fin sino inicio
        si izquierda-libre entonces inicio
            si junto-a-zumbador entonces inicio
                gira(2);
                mientras frente-libre hacer avanza;
                gira(3);
                avanza;
                gira(3);
                contar(a);
            fin sino inicio
                gira(2);
                mientras frente-libre hacer avanza;
                gira(3);
                avanza;
                gira(3);
                contar(sucede(a));
            fin;
        fin;
        repetir sucede(a) veces deja-zumbador;
        apagate;
    fin;
fin;

    inicia-ejecucion

        mientras no orientado-al-norte hacer gira(1);
        mientras frente-libre hacer avanza;
        gira(3);
        mientras frente-libre hacer avanza;
        gira(2);
        si junto-a-zumbador entonces inicio
            mientras junto-a-zumbador hacer coge-zumbador;
            apagate;
        fin;
        marcar;
        contar(0);

        apagate;
    termina-ejecucion
finalizar-programa
