iniciar-programa
define-nueva-instruccion g(n) como
repetir n veces gira-izquierda;
define-nueva-instruccion dfs como
inicio
    repetir 4 veces
    inicio
        si frente-libre y no-orientado-al-este y no-orientado-al-norte entonces
        inicio
            avanza;
            si no-junto-a-zumbador entonces
            inicio
                deja-zumbador;
                dfs;
            fin;
            g(2);
            avanza;
            g(2);
        fin;
        gira-izquierda;
    fin;
fin;
define-nueva-instruccion pasa(n) como
inicio
    si junto-a-zumbador entonces
    inicio
        coge-zumbador;
        pasa(sucede(n))
    fin
    sino
    inicio
        avanza;
        repetir n veces deja-zumbador;
    fin;
fin;
define-nueva-instruccion dfsc como
inicio
    repetir 4 veces
    inicio
        si frente-libre entonces
        inicio
            avanza;
            si junto-a-zumbador entonces
            inicio
                coge-zumbador;
                si junto-a-zumbador entonces
                inicio
                    deja-zumbador;
                    g(2);
                    avanza;
                    g(2);
                fin
                sino
                inicio
                    deja-zumbador;
                    g(2);
                    avanza;
                    g(2);
                    pasa(0);
                    dfsc;
                    g(2);
                    pasa(0);
                    g(2);
                fin;
            fin
            sino
            inicio
                g(2);
                avanza;
                g(2);
            fin;
        fin;
        gira-izquierda;
    fin;
fin;
define-nueva-instruccion distancia(n) como
inicio
    si frente-libre entonces
    inicio
        avanza;
        distancia(sucede(n))
    fin
    sino
    inicio
        gira-izquierda;
        repetir 13 veces
        si orientado-al-norte entonces
        inicio
            si frente-libre entonces
            avanza
            sino
            g(2);
        fin;
        si orientado-al-norte y frente-bloqueado entonces
        inicio
            si si-es-cero (precede(precede(precede(precede(precede(precede(precede(precede(precede(precede(precede(precede(precede(precede(precede(precede(precede(precede(precede(precede(precede(precede(precede(precede(precede(precede(precede(n)))))))))))))))))))))))))))) entonces
            inicio
                repetir 292 veces deja-zumbador;
                apagate;
            fin
            sino
            inicio
                mientras no-orientado-al-sur hacer gira-izquierda;
                sal-de-instruccion;
            fin;
        fin
        sino
        inicio
            mientras no-orientado-al-norte hacer gira-izquierda;
            mientras frente-libre hacer
            avanza;
            g(2);
            sal-de-instruccion;
        fin;
    fin;
fin;
    inicia-ejecucion
        mientras no-orientado-al-oeste hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        gira-izquierda;
        mientras frente-libre hacer avanza;
        gira-izquierda;
        distancia(0);
        si no-junto-a-zumbador entonces
        deja-zumbador
        sino
        inicio
            repetir 2 veces coge-zumbador;
            apagate;
        fin;
        dfs;
        dfsc;
        apagate;
    termina-ejecucion
finalizar-programa
