iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion posicionarse como inicio
        norte;
        mientras frente-libre hacer avanza;
        este;
        mientras frente-libre hacer avanza;
        sur;
        fin;

    define-nueva-instruccion buscar como inicio
        si no-junto-a-zumbador entonces inicio
            deja-zumbador;
            buscar;

            sur;
            si frente-libre entonces inicio
                avanza;
                buscar;
                norte;
                avanza;
                fin;

            oeste;
            si frente-libre entonces inicio
                avanza;
                buscar;
                este;
                avanza;
                fin;
            fin;
        fin;

    define-nueva-instruccion camina como inicio
        si frente-libre entonces inicio
            avanza;
            fin sino inicio
            si orientado-al-oeste entonces inicio
                sur;
                si frente-libre entonces inicio
                    avanza;
                    este;
                    fin;
                fin sino inicio
                sur;
                si frente-libre entonces inicio
                    avanza;
                    oeste;
                    fin;
                fin;
            fin;
        fin;

    define-nueva-instruccion contarUnos como inicio
        si no-orientado-al-sur entonces inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si junto-a-zumbador entonces inicio
                    (*dos zumbadores*)
                    deja-zumbador;
                    camina;
                    contarUnos;
                    fin sino inicio
                    (*un zumbador*)
                    camina;
                    contarUnos;
                    deja-zumbador;
                    fin;
                fin sino inicio
                (*cero zumbadores*)
                camina;
                contarUnos;
                fin;
            fin sino inicio
            posicionarse;
            oeste;
            fin;
        fin;

    inicia-ejecucion
        posicionarse;
        si no-junto-a-zumbador entonces inicio
            buscar;
            oeste;
            contarUnos;
            fin sino inicio
            mientras junto-a-zumbador hacer coge-zumbador;
            fin;
        apagate;
    termina-ejecucion
finalizar-programa
