iniciar-programa
    define-nueva-instruccion gira (n) como inicio
        repetir n veces
            gira-izquierda;
    fin;
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer
            gira (1);
    fin;
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer
            gira (1);
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer
            gira (1);
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer
            gira (1);
    fin;
    define-nueva-instruccion orienta como inicio
        norte;
        mientras frente-libre hacer
            avanza;
        este;
        mientras frente-libre hacer
            avanza;
    fin;
    define-nueva-instruccion busca como inicio
        si no-junto-a-zumbador entonces inicio
            deja-zumbador;
            sur;
            si frente-libre entonces inicio
                avanza;
                busca;
                norte;
                avanza;
            fin;
            oeste;
            si frente-libre entonces inicio
                avanza;
                busca;
                este;
                avanza;
            fin;
        fin;
    fin;
    define-nueva-instruccion cuenta (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si no-junto-a-zumbador entonces inicio
                cuenta (sucede(n));
            fin
            sino inicio
                deja-zumbador;
                si frente-libre entonces inicio
                    avanza;
                    cuenta (n);
                fin
                sino inicio
                    si frente-bloqueado y derecha-libre entonces inicio
                        sur;
                        mientras frente-libre hacer
                            avanza;
                        este;
                        avanza;
                        norte;
                        cuenta (n);
                    fin
                    sino inicio
                        repetir n veces
                            deja-zumbador;
                        apagate;
                    fin;
                fin;
            fin;
        fin
        sino inicio
            si frente-libre entonces inicio
                avanza;
                cuenta (n);
            fin
            sino inicio
                si frente-bloqueado y derecha-libre entonces inicio
                    sur;
                    mientras frente-libre hacer
                        avanza;
                    este;
                    avanza;
                    norte;
                    cuenta (n);
                fin
                sino inicio
                    repetir n veces
                        deja-zumbador;
                    apagate;
                fin;
            fin;
        fin;
    fin;
    inicia-ejecucion
        orienta;
        si junto-a-zumbador entonces inicio
            mientras junto-a-zumbador hacer
                coge-zumbador;
           apagate;
        fin;
        busca;
        sur;
        mientras frente-libre hacer
            avanza;
        oeste;
        mientras frente-libre hacer
            avanza;
        norte;
        cuenta (0);
        apagate;
    termina-ejecucion
finalizar-programa