iniciar-programa
define-nueva-instruccion media-vuelta como repetir 2 veces gira-izquierda;
define-nueva-instruccion derecha como repetir 3 veces gira-izquierda;

define-nueva-instruccion busca-derecha como
    inicio
        avanza;
    si no-junto-a-zumbador entonces
        inicio
            media-vuelta;
            avanza;
            gira-izquierda;
            avanza;
            media-vuelta;
        fin;
    fin;

define-nueva-instruccion busca-izquierda como
    inicio
        gira-izquierda;
        avanza;
    si no-junto-a-zumbador entonces
        inicio
            media-vuelta;
            avanza;
            busca-derecha;
        fin;
    fin;

define-nueva-instruccion orientar como
    inicio
        avanza;
        media-vuelta;
    si junto-a-zumbador entonces
        inicio
            avanza;
            media-vuelta;
        fin
    sino
        inicio
            avanza;
            gira-izquierda;
            avanza;
            media-vuelta;
        si junto-a-zumbador entonces
            inicio
                avanza;
                media-vuelta;
            fin
        sino
            inicio
                avanza;
                gira-izquierda;
                avanza;
                media-vuelta;
            si junto-a-zumbador entonces
                inicio
                    avanza;
                    media-vuelta;
                fin
            sino
                inicio
                    avanza;
                    gira-izquierda;
                    avanza;
                    media-vuelta;
                si junto-a-zumbador entonces
                    inicio
                        avanza;
                        media-vuelta;
                    fin
                sino
                    inicio
                        avanza;
                        gira-izquierda;
                    fin;
                fin;
            fin;
        fin;
    fin;

define-nueva-instruccion seguir como
    inicio
    si junto-a-zumbador entonces
        inicio
            avanza;
        si no-junto-a-zumbador entonces
            inicio
                media-vuelta;
                avanza;
                busca-izquierda;
            fin;
        fin;
    fin;

define-prototipo-instruccion checa(m);
define-prototipo-instruccion suma(n);
define-prototipo-instruccion resta(x);

define-nueva-instruccion saber (d) como
    inicio
    si junto-a-zumbador entonces
        inicio
            coge-zumbador;
        si junto-a-zumbador entonces
            inicio
                coge-zumbador;
                saber(sucede(sucede(d)));
            fin sino
            inicio
                repetir d veces deja-zumbador;
                deja-zumbador;
                media-vuelta;
                avanza;
            mientras junto-a-zumbador hacer coge-zumbador;
                media-vuelta;
            fin;
        fin sino
        inicio
            repetir d veces deja-zumbador;
        fin;
    fin;

define-nueva-instruccion checa (m) como
    inicio
    si junto-a-zumbador entonces
        inicio
            saber(0);
        si junto-a-zumbador entonces resta(m) sino
            inicio
                avanza;
                suma(m);
            fin;
        fin sino
        inicio
            avanza;
            derecha;
            avanza;
            repetir m veces deja-zumbador;
            apagate;
        fin;
    fin;

define-nueva-instruccion resta(x) como
    inicio
    si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            resta(precede(x));
        fin sino
        inicio
            deja-zumbador;
            seguir;
            checa(x);
        fin;
    fin;

define-nueva-instruccion suma(n) como
    inicio
    si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            suma(sucede(n));
        fin sino
        inicio
            deja-zumbador;
            seguir;
            checa(n);
        fin;
    fin;

    inicia-ejecucion
        orientar;
        mientras junto-a-zumbador hacer seguir;
        avanza;
        checa(0);
        apagate;
    termina-ejecucion
finalizar-programa
