iniciar-programa
define-prototipo-instruccion final;
define-nueva-instruccion paridad como
inicio
   si junto-a-zumbador entonces
   inicio
      coge-zumbador;
      si no-junto-a-zumbador entonces
      inicio
         mientras no orientado-al-este hacer
            gira-izquierda;
         deja-zumbador;
      fin
      sino
      inicio
        coge-zumbador;
        paridad;
        deja-zumbador;
        deja-zumbador;
      fin;
   fin
   sino
      mientras no orientado-al-oeste hacer
         gira-izquierda;
fin;

define-nueva-instruccion acarrea como
inicio
   si junto-a-zumbador entonces
   inicio
      coge-zumbador;
      acarrea;
      deja-zumbador;
   fin
   sino
      avanza;
fin;
define-nueva-instruccion resta(n) como
inicio
   si junto-a-zumbador entonces
   inicio
      coge-zumbador;
      resta(sucede(n));
   fin
   sino
   inicio
      avanza;
      avanza;
      repetir n veces
         si junto-a-zumbador entonces
            coge-zumbador;
   fin;
fin;

define-nueva-instruccion gira(n) como
inicio
   repetir n veces
      gira-izquierda;
fin;
define-nueva-instruccion lleva como
inicio
   gira(3);
   repetir 3 veces
   inicio
      si frente-libre entonces
      inicio
         avanza;
         si junto-a-zumbador entonces
         inicio
            lleva;
            sal-de-instruccion;
         fin;
         gira(2);
         avanza;
         gira(2);
      fin;
      gira-izquierda;
   fin;
   sal-de-instruccion;
fin;
define-nueva-instruccion come(n) como
inicio
   si junto-a-zumbador entonces
   inicio
      coge-zumbador;
      come(sucede(n));
   fin
   sino
   inicio
     lleva;
     mientras no-orientado-al-sur hacer
        gira(1);
     avanza;
     repetir n veces
        deja-zumbador;
     paridad;
     acarrea;
     gira(2);
     avanza;
     mientras no-orientado-al-norte hacer
        gira(1);
     avanza;
     lleva;
    si junto-a-zumbador entonces
    come(0)
    sino
    inicio
       avanza;
       gira(3);
       avanza;
       gira(2);
       resta(0);
       gira(1);
       acarrea;
       apagate;
    fin;
   fin;
fin;
define-nueva-instruccion final como
inicio
   gira(3);
   repetir 3 veces
   inicio
      si frente-libre entonces
      inicio
         avanza;
         si junto-a-zumbador entonces
            final;
         gira(2);
         avanza;
         gira(2);
      fin;
      gira-izquierda;
   fin;
   come(0);
   gira(2);
fin;

inicia-ejecucion
  mientras no-orientado-al-norte hacer
     gira-izquierda;
  lleva;
  come(0);
  apagate;
  termina-ejecucion
finalizar-programa
