iniciar-programa

    define-nueva-instruccion gira-derecha como inicio
        repetir 3 veces gira-izquierda;
    fin;
    define-nueva-instruccion media-vuelta como inicio
        repetir 2 veces gira-izquierda;
    fin;

    define-nueva-instruccion comparaIzq(n) como inicio
        repetir n veces inicio
            si junto-a-zumbador entonces coge-zumbador;
        fin;
        si no junto-a-zumbador entonces inicio
            media-vuelta;
            avanza;
            gira-derecha;
            repetir n veces inicio
                Si algun-zumbador-en-la-mochila entonces inicio
                    deja-zumbador;
                    si frente-libre entonces avanza;
                fin;
            fin;
            apagate;
        fin;
        mientras junto-a-zumbador hacer coge-zumbador;
    fin;

    define-nueva-instruccion comparaDer(n) como inicio
        repetir n veces inicio
            si junto-a-zumbador entonces coge-zumbador;
        fin;
        si no junto-a-zumbador entonces inicio
            media-vuelta;
            avanza;
            gira-izquierda;
            repetir n veces inicio
                Si algun-zumbador-en-la-mochila entonces inicio
                    deja-zumbador;
                    si frente-libre entonces avanza;
                fin;
            fin;
            apagate;
        fin;
        mientras junto-a-zumbador hacer coge-zumbador;
    fin;

    define-nueva-instruccion revisaDer(n) como inicio
        si no junto-a-zumbador entonces inicio
            si frente-libre entonces inicio
                avanza;
                revisaDer(sucede(n));
            fin sino inicio
                media-vuelta;
                repetir n veces avanza;
                gira-derecha;
                avanza;
                comparaDer(sucede(n));
            fin;
        fin sino inicio
            media-vuelta;
            repetir n veces avanza;
            gira-derecha;
            avanza;
            comparaDer(n);
        fin;
    fin;

    define-nueva-instruccion revisaIzq(n) como inicio
        si no junto-a-zumbador entonces inicio
            si frente-libre entonces inicio
                avanza;
                revisaIzq(sucede(n));
            fin sino inicio
                media-vuelta;
                repetir n veces avanza;
                gira-izquierda;
                avanza;
                comparaIzq(sucede(n));
            fin;
        fin sino inicio
            media-vuelta;
            repetir n veces avanza;
            gira-izquierda;
            avanza;
            comparaIzq(n);
        fin;
    fin;

    define-nueva-instruccion final(n) como inicio
        mientras junto-a-zumbador o no junto-a-zumbador hacer inicio
            gira-izquierda;
            avanza;
            gira-derecha;
            revisaIzq(0);
            repetir n veces deja-zumbador;
            avanza;
            gira-izquierda;
            revisaDer(0);
            gira-derecha;
            repetir n veces deja-zumbador;
            repetir n veces coge-zumbador;
            si frente-libre entonces inicio
                avanza;
                repetir n veces deja-zumbador;
            fin sino inicio
                apagate;
            fin;
         fin;
     fin;

    define-nueva-instruccion cuenta(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si frente-libre entonces inicio
                avanza;
                cuenta(sucede(n));
            fin sino inicio
                media-vuelta;
                repetir n veces avanza;
                media-vuelta;
                repetir sucede(n) veces deja-zumbador;
                final(sucede(n));
            fin;
        fin sino inicio
            media-vuelta;
            repetir n veces avanza;
            media-vuelta;
            repetir n veces deja-zumbador;
            final(n);
        fin;
    fin;

    inicia-ejecucion
        si junto-a-zumbador entonces inicio
            cuenta(0);
        fin;
        apagate;
    termina-ejecucion
finalizar-programa
