iniciar-programa
    define-nueva-instruccion gira(n) como inicio
        repetir n veces
            gira-izquierda;
    fin;
    define-nueva-instruccion checa(n) como inicio
        si no-junto-a-zumbador y no(si-es-cero(n)) entonces inicio
            si algun-zumbador-en-la-mochila entonces inicio
                deja-zumbador;
            fin
            sino inicio
                gira(2);
                avanza;
                mientras junto-a-zumbador hacer inicio
                    si junto-a-zumbador entonces inicio
                        coge-zumbador;
                        si junto-a-zumbador entonces inicio
                            gira(2);
                            mientras junto-a-zumbador hacer
                                avanza;
                            deja-zumbador;
                            apagate;
                        fin
                        sino inicio
                            deja-zumbador;
                            avanza;
                        fin;
                    fin;

                fin;
            fin;
            avanza;
            checa(precede(n));
        fin
        sino inicio
            si junto-a-zumbador entonces inicio
                gira(2);
                avanza;
                mientras junto-a-zumbador hacer inicio
                    si junto-a-zumbador entonces inicio
                        coge-zumbador;
                        si junto-a-zumbador entonces inicio
                            coge-zumbador;
                            gira(2);
                        fin
                        sino inicio
                            avanza;
                        fin;
                    fin;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion revisa(n) como inicio
        gira(1);
        avanza;
        gira(3);
        si no-junto-a-zumbador entonces inicio
            repetir 2 veces inicio
                si algun-zumbador-en-la-mochila entonces inicio
                   deja-zumbador;
                fin
                sino inicio
                    apagate;
                fin;
            fin;
            avanza;
            checa(precede(n));
        fin;
        gira(3);
        avanza;
        avanza;
        gira(1);
        si no-junto-a-zumbador entonces inicio
            repetir 2 veces inicio
                si algun-zumbador-en-la-mochila entonces inicio
                   deja-zumbador;
                fin
                sino inicio
                    apagate;
                fin;
            fin;
            avanza;
            checa(precede(n));
        fin;
        gira(1);
        avanza;
        gira(3);
        avanza;
        revisa(n);
    fin;
    define-nueva-instruccion cuenta(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si frente-libre entonces
                avanza;
            cuenta(sucede(n));
        fin
        sino inicio
            si frente-libre entonces inicio
                gira(2);
                repetir n veces
                    avanza;
                gira(2);
                revisa(n);
            fin
            sino inicio
                gira(2);
                repetir precede(n) veces
                    avanza;
                gira(2);
                revisa(n);
            fin;
        fin;
    fin;
    inicia-ejecucion
        si no-junto-a-zumbador entonces
            apagate;
        cuenta(0);
        apagate;
    termina-ejecucion
finalizar-programa