iniciar-programa
define-nueva-instruccion tomarlargo como
inicio
  mientras junto-a-zumbador y frente-libre hacer avanza;
  repetir 2 veces gira-izquierda;
  si no-junto-a-zumbador y frente-libre entonces avanza;
  mientras junto-a-zumbador hacer
    inicio
      coge-zumbador;
      si frente-libre entonces
        inicio
          avanza;
          si no-junto-a-zumbador entonces
            inicio
              repetir 2 veces gira-izquierda;
              avanza;
            fin;
        fin
       sino repetir 2 veces gira-izquierda;
    fin;
fin;

define-nueva-instruccion acomodar como
inicio
  mientras junto-a-zumbador hacer coge-zumbador;
  mientras algun-zumbador-en-la-mochila hacer
    inicio
       deja-zumbador;
       si frente-libre y algun-zumbador-en-la-mochila entonces avanza;
    fin;
  apagate;
fin;

define-nueva-instruccion comprobar(n) como
inicio
  si no-junto-a-zumbador y frente-libre entonces
    inicio
      si frente-libre entonces avanza;
      comprobar(sucede(n));
    fin
  sino
    inicio
      si frente-bloqueado y no-junto-a-zumbador entonces
        inicio
          repetir 2 veces gira-izquierda;
          repetir n veces avanza;
          repetir 2 veces gira-izquierda;
          repetir sucede (n) veces si algun-zumbador-en-la-mochila entonces deja-zumbador;
          si algun-zumbador-en-la-mochila entonces mientras junto-a-zumbador hacer coge-zumbador
          sino acomodar;
        fin
      sino
        inicio
          repetir 2 veces gira-izquierda;
          repetir n veces avanza;
          repetir 2 veces gira-izquierda;
          repetir n veces si algun-zumbador-en-la-mochila entonces deja-zumbador;
          si algun-zumbador-en-la-mochila entonces mientras junto-a-zumbador hacer coge-zumbador
          sino acomodar;
        fin;

    fin;
fin;

define-nueva-instruccion izquierda como
inicio
  gira-izquierda;
  avanza;
  repetir 3 veces gira-izquierda;
  si no-junto-a-zumbador entonces comprobar(0);
fin;

    inicia-ejecucion
        tomarlargo;
        mientras algun-zumbador-en-la-mochila hacer
          inicio
             izquierda;
             repetir 3 veces gira-izquierda;
             repetir 2 veces avanza;
             gira-izquierda;
             si no-junto-a-zumbador entonces comprobar(0);
             gira-izquierda;
             avanza;
             repetir 3 veces gira-izquierda;
             avanza;

          fin;
        apagate;
    termina-ejecucion
finalizar-programa
