iniciar-programa
define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

define-nueva-instruccion toma(n) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        toma(n);
        coge-zumbador;
    fin sino inicio
        repetir n veces deja-zumbador;
    fin;
fin;

define-nueva-instruccion ver(n) como inicio
    si orientado-al-norte y junto-a-zumbador entonces inicio
        repetir n veces inicio
            si junto-a-zumbador y orientado-al-norte entonces inicio
                coge-zumbador;
            fin sino inicio
                este;
                deja-zumbador;
            fin;
        fin;
            ver(n);
            si orientado-al-norte entonces inicio
                repetir n veces deja-zumbador;
            fin sino inicio
                si orientado-al-este entonces inicio
                    toma(n);
                    oeste;
                fin sino inicio
                    repetir n veces deja-zumbador;
                fin;
            fin;
    fin;
fin;

define-nueva-instruccion busca(n) como inicio
    si no si-es-cero(n) entonces inicio
        si junto-a-zumbador y no-orientado-al-sur entonces inicio

            si no-orientado-al-sur entonces inicio
                norte;
                si frente-libre entonces inicio
                    avanza;
                    ver(n);
                    si orientado-al-norte entonces inicio
                        busca(precede(n));
                        si no-orientado-al-sur entonces inicio
                            sur;
                            avanza;
                            norte;
                        fin sino inicio
                            deja-zumbador;
                        fin;
                    fin sino inicio
                        sur;
                        avanza;
                        norte;
                    fin;
                fin;
            fin;

            si no-orientado-al-sur entonces inicio
                este;
                si frente-libre entonces inicio
                    avanza;
                    norte;
                    ver(n);
                    si orientado-al-norte entonces inicio
                        busca(precede(n));
                        si no-orientado-al-sur entonces inicio
                            oeste;
                            avanza;
                        fin sino inicio
                            deja-zumbador;
                        fin;
                    fin sino inicio
                        oeste;
                        avanza;
                    fin;
                fin;
            fin;

            si no-orientado-al-sur entonces inicio
                sur;
                si frente-libre entonces inicio
                    avanza;
                    norte;
                    ver(n);
                    si orientado-al-norte entonces inicio
                        busca(precede(n));
                        si no-orientado-al-sur entonces inicio
                            norte;
                            avanza;
                        fin sino inicio
                            deja-zumbador;
                        fin;
                    fin sino inicio
                        norte;
                        avanza;
                    fin;
                fin sino inicio
                    norte;
                fin;
            fin;

            si no-orientado-al-sur entonces inicio
                oeste;
                si frente-libre entonces inicio
                    avanza;
                    norte;
                    ver(n);
                    si orientado-al-norte entonces inicio
                        busca(precede(n));
                        si no-orientado-al-sur entonces inicio
                            este;
                            avanza;
                        fin sino inicio
                            deja-zumbador;
                        fin;
                    fin sino inicio
                        este;
                        avanza;
                    fin;
                fin;
            fin;

        fin sino inicio
            sur;
        fin;
    fin sino inicio
        norte;
        si frente-libre entonces inicio
            avanza;
            si no-junto-a-zumbador y (derecha-libre o izquierda-libre o frente-libre) entonces inicio
                sur;
            fin sino inicio
                sur;
                avanza;
                este;
            fin;
        fin sino inicio
            este;
        fin;
        si orientado-al-este entonces inicio
            si frente-libre entonces inicio
                avanza;
                si no-junto-a-zumbador y (derecha-libre o izquierda-libre o frente-libre) entonces inicio
                    sur;
                fin sino inicio
                    oeste;
                    avanza;
                fin;
            fin sino inicio
                oeste;
            fin;
        fin;
        si orientado-al-oeste entonces inicio
            sur;
            si frente-libre entonces inicio
                avanza;
                si no-junto-a-zumbador y (derecha-libre o izquierda-libre o frente-libre) entonces inicio

                fin sino inicio
                    norte;
                    avanza;
                fin;
            fin sino inicio
                norte;
            fin;
        fin;
        si orientado-al-norte entonces inicio
            oeste;
            si frente-libre entonces inicio
                avanza;
                si no-junto-a-zumbador y (derecha-libre o izquierda-libre o frente-libre) entonces inicio
                    sur;
                fin sino inicio
                    este;
                    avanza;
                fin;
            fin;
        fin;
    fin;
fin;


define-nueva-instruccion infinito(n) como inicio
    si no-orientado-al-sur entonces inicio
        repetir n veces deja-zumbador;
        deja-zumbador;
        busca(n);
        mientras junto-a-zumbador hacer coge-zumbador;
        infinito(sucede(n));
    fin;
fin;

define-nueva-instruccion k como inicio
    si frente-libre entonces inicio
        avanza;
        k;
        si frente-libre entonces avanza;
    fin sino inicio
        si derecha-libre o izquierda-libre o frente-libre entonces inicio
            repetir 2 veces gira-izquierda;
        fin;
    fin;
fin;

define-nueva-instruccion ir como inicio
    si izquierda-libre o frente-libre o derecha-libre entonces inicio
        si frente-libre y derecha-bloqueada entonces inicio
            avanza;
            k;
            si derecha-libre o izquierda-libre o frente-libre entonces inicio
                repetir 2 veces gira-izquierda;
            fin;
            ir;
        fin sino inicio
            si frente-bloqueado y izquierda-libre y derecha-bloqueada entonces inicio
                gira-izquierda;
                avanza;
                k;
                si derecha-libre o izquierda-libre o frente-libre entonces inicio
                    repetir 2 veces gira-izquierda;
                fin;
                ir;
            fin sino inicio
                si derecha-libre entonces inicio
                    repetir 3 veces gira-izquierda;
                    avanza;
                    k;
                    si derecha-libre o izquierda-libre o frente-libre entonces inicio
                        repetir 2 veces gira-izquierda;
                    fin;
                    ir;
                fin;
            fin;
        fin;
    fin;
fin;

    inicia-ejecucion
    oeste;
    mientras frente-libre hacer avanza;
    norte;
    mientras frente-libre hacer avanza;
    oeste;
    mientras frente-libre hacer avanza;
    norte;
    mientras frente-libre hacer avanza;
    este;
    si frente-libre entonces inicio
        avanza;
        sur;
        si frente-libre entonces avanza;
        este;
        si frente-libre entonces inicio
            avanza;
            si frente-libre entonces avanza;
        fin;
    fin;
    norte;
    mientras frente-libre y derecha-libre y izquierda-libre hacer avanza;
    mientras derecha-libre hacer gira-izquierda;
    ir;
    norte;
    infinito(0);
        apagate;
    termina-ejecucion
finalizar-programa
