iniciar-programa

    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion quita(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            quita(n);
            coge-zumbador;
        fin sino inicio
            repetir n veces deja-zumbador;
        fin;
    fin;

    define-nueva-instruccion compara(n) como inicio
        repetir n veces inicio
            si junto-a-zumbador y no orientado-al-sur entonces inicio
                coge-zumbador;
            fin sino inicio
                sur;
                deja-zumbador;
            fin;
        fin;
        si orientado-al-norte entonces inicio
            mientras junto-a-zumbador hacer coge-zumbador;
            repetir n veces deja-zumbador;
        fin sino inicio
            quita(n);
        fin;
    fin;

    define-nueva-instruccion recoge(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            recoge(sucede(n));
        fin sino inicio
            repetir n veces deja-zumbador;
            repetir 101 veces inicio
                si junto-a-zumbador entonces coge-zumbador;
            fin;
            si junto-a-zumbador entonces inicio
                mientras junto-a-zumbador hacer coge-zumbador;
                repetir n veces deja-zumbador;
                sur;
            fin sino inicio
                repetir n veces deja-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion revisa(n) como inicio
        norte;
        repetir n veces inicio
            si junto-a-zumbador y no orientado-al-sur entonces inicio
                coge-zumbador;
            fin sino inicio
                sur;
                deja-zumbador;
            fin;
        fin;
        si orientado-al-norte entonces inicio
            repetir n veces deja-zumbador;
        fin sino inicio
            quita(n);
        fin;
    fin;

    define-nueva-instruccion divide(n) como inicio
        si si-es-cero(n) entonces inicio
            norte;
            mientras junto-a-zumbador hacer coge-zumbador;
        fin;
        si junto-a-zumbador y no orientado-al-sur y no si-es-cero(n) entonces inicio
            revisa(n);
            si orientado-al-norte entonces inicio
                repetir n veces coge-zumbador;
                divide(n);
                repetir n veces deja-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion busqueda(n) como inicio
        si junto-a-zumbador y (derecha-libre o izquierda-libre o frente-libre) entonces inicio
            norte;
            recoge(0);
            si orientado-al-norte entonces inicio
                divide(n);
                si orientado-al-este entonces inicio
                    repetir n veces coge-zumbador;
                fin;
                si orientado-al-norte entonces inicio
                    repetir 101 veces deja-zumbador;
                    norte;
                    si frente-libre entonces inicio
                        avanza;
                        busqueda(sucede(n));
                        sur;
                        avanza;
                    fin;
                    sur;
                    si frente-libre entonces inicio
                        avanza;
                        busqueda(sucede(n));
                        norte;
                        avanza;
                    fin;
                    este;
                    si frente-libre entonces inicio
                        avanza;
                        busqueda(sucede(n));
                        oeste;
                        avanza;
                    fin;
                    oeste;
                    si frente-libre entonces inicio
                        avanza;
                        busqueda(sucede(n));
                        este;
                        avanza;
                    fin;
                    repetir 101 veces coge-zumbador;
                fin;
            fin;
        fin sino inicio
            si junto-a-zumbador entonces inicio
                norte;
                compara(n);
            fin sino inicio
                repetir n veces deja-zumbador;
            fin;
        fin;
    fin;

    inicia-ejecucion
        si frente-bloqueado y izquierda-bloqueada y derecha-bloqueada entonces apagate;
        repetir 101 veces deja-zumbador;
        busqueda(0);
        apagate;
    termina-ejecucion
finalizar-programa
